[gentoo-commits] repo/proj/libressl:master commit in: mail-filter/imapfilter/

[Quentin Retornaz]

commit:     6d73e3a01765917917c7afe9bb8f8c14a5e22e2e
Author:     orbea <orbea <AT> riseup <DOT> net>
AuthorDate: Thu Jul  7 22:24:50 2022 +0000
Commit:     Quentin Retornaz <gentoo <AT> retornaz <DOT> com>
CommitDate: Sun Jul 10 22:50:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/libressl.git/commit/?id=6d73e3a0

mail-filter/imapfilter: Add 2.7.5-r1

Signed-off-by: orbea <orbea <AT> riseup.net>
Signed-off-by: Quentin Retornaz <gentoo <AT> retornaz.com>

 mail-filter/imapfilter/imapfilter-2.7.5-r1.ebuild | 50 +++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/mail-filter/imapfilter/imapfilter-2.7.5-r1.ebuild 
b/mail-filter/imapfilter/imapfilter-2.7.5-r1.ebuild
new file mode 100644
index 0000000..deaa832
--- /dev/null
+++ b/mail-filter/imapfilter/imapfilter-2.7.5-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit lua-single toolchain-funcs
+
+DESCRIPTION="An IMAP mail filtering utility"
+HOMEPAGE="https://github.com/lefcha/imapfilter";
+SRC_URI="https://github.com/lefcha/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+       dev-libs/openssl:0=
+       dev-libs/libpcre2
+       ${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+
+DOCS="AUTHORS NEWS README samples/*"
+
+PATCHES=( "${FILESDIR}"/${P}-libressl.patch )
+
+src_prepare() {
+       default
+       sed -i -e "/^PREFIX/s:/usr/local:${EPREFIX}/usr:" \
+               -e "/^MANDIR/s:man:share/man:" \
+               -e "/^CFLAGS/s:CFLAGS =:CFLAGS +=:" \
+               -e "/^CFLAGS/s/-O//" \
+               src/Makefile || die
+}
+
+src_compile() {
+       emake \
+               CC="$(tc-getCC)" \
+               LDFLAGS="${LDFLAGS}" \
+               INCDIRS=$(lua_get_CFLAGS) \
+               LIBLUA=$(lua_get_LIBS)
+}
+
+src_install() {
+       default
+       doman doc/imapfilter.1 doc/imapfilter_config.5
+}