commit: b4091612bc10dbd7ded395560b6c50f5a2ac91a4
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 20 19:46:12 2022 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Jun 20 19:53:50 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b4091612
dev-libs/link-grammar: Version bump to 5.10.5
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
dev-libs/link-grammar/Manifest | 1 +
dev-libs/link-grammar/link-grammar-5.10.5.ebuild | 113 +++++++++++++++++++++++
2 files changed, 114 insertions(+)
diff --git a/dev-libs/link-grammar/Manifest b/dev-libs/link-grammar/Manifest
index a09777eb5c2c..a2715fe3e05d 100644
--- a/dev-libs/link-grammar/Manifest
+++ b/dev-libs/link-grammar/Manifest
@@ -1 +1,2 @@
DIST link-grammar-5.10.4.tar.gz 4593602 BLAKE2B
0515aed27ae8df85ceddb9685ce90db2b6e7671235b9b445b6728b1ac417d6d43b3705566066ff9735fc98c32746342c224f2399bb0f2573784f20b5f998e7be
SHA512
a215694f76e15286c478884ea8a13b32976d06ea45d10897dc1b303f256a2c0af94c9f90da26b314ce5e03009b494ab526c729b66f2b1ed46ff3e8b02cb6fd08
+DIST link-grammar-5.10.5.tar.gz 4637765 BLAKE2B
d280a06492462725c9c62352b6bf4fb0a11a09b2b3049e41d9a078fa2ad37c8ef0f0e99e05039e355e81d127c168024068319a4fcf64caa840c00c165ed22f11
SHA512
09774f7ce01bc7ec9912162297c9b7be176e655b70981a147d53245c015f62581e7f45c005d0590d1a65e870e3c2ac4288517012fd9caa9887e4fd86d8e6aa05
diff --git a/dev-libs/link-grammar/link-grammar-5.10.5.ebuild
b/dev-libs/link-grammar/link-grammar-5.10.5.ebuild
new file mode 100644
index 000000000000..9cd72d301f29
--- /dev/null
+++ b/dev-libs/link-grammar/link-grammar-5.10.5.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit autotools python-r1 out-of-source
+
+DESCRIPTION="A Syntactic English parser"
+HOMEPAGE="https://www.abisource.com/projects/link-grammar/
https://www.link.cs.cmu.edu/link/";
+SRC_URI="https://www.abisource.com/downloads/${PN}/${PV}/${P}.tar.gz";
+
+LICENSE="LGPL-2.1"
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="aspell +hunspell python" # pcre
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# XXX: sqlite is automagic
+# Does not build with >=sci-mathematics/minisat-2, bug #593662
+# add pcre support: pcre? ( dev-libs/libpcre )
+RDEPEND="
+ dev-db/sqlite:3
+ aspell? ( app-text/aspell )
+ hunspell? ( app-text/hunspell )
+ python? ( ${PYTHON_DEPS} )
+ !sci-mathematics/minisat"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ dev-lang/swig:0
+ sys-devel/autoconf-archive
+ virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${PN}-5.8.1-lld.patch )
+
+pkg_setup() {
+ if use aspell && use hunspell; then
+ ewarn "You have enabled 'aspell' and 'hunspell' support, but
both cannot coexist,"
+ ewarn "only hunspell will be built. Press Ctrl+C and set only
'aspell' USE flag if"
+ ewarn "you want aspell support."
+ fi
+}
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+my_src_configure() {
+ local myconf=(
+ --disable-maintainer-mode
+ --disable-editline
+ # java is hopelessly broken, invokes maven at build time (bug
#806157)
+ --disable-java-bindings
+ --disable-perl-bindings
+ --disable-static
+ --enable-sat-solver=bundled
+ $(use_enable aspell)
+ $(use_enable hunspell)
+ $(usev hunspell
--with-hunspell-dictdir="${EPREFIX}"/usr/share/myspell)
+ # $(use_enable pcre regex-tokenizer)
+ # $(use_with pcre)
+ )
+
+ econf \
+ --disable-python-bindings \
+ "${myconf[@]}"
+
+ if use python; then
+ python_configure() {
+ econf \
+ --enable-python-bindings \
+ "${myconf[@]}"
+ }
+ python_foreach_impl run_in_build_dir python_configure
+ fi
+}
+
+my_src_compile() {
+ local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+ default
+
+ if use python; then
+ python_compile() {
+ emake -C bindings/python \
+ VPATH="${S}:${MAIN_BUILD_DIR}" \
+
_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
\
+
_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
+ }
+ python_foreach_impl run_in_build_dir python_compile
+ fi
+}
+
+my_src_install() {
+ local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+ default
+
+ if use python; then
+ python_install() {
+ emake -C bindings/python \
+ VPATH="${S}:${MAIN_BUILD_DIR}" \
+
_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
\
+
_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+ DESTDIR="${D}" \
+ install
+ }
+ python_foreach_impl run_in_build_dir python_install
+ fi
+
+ # no static archives
+ find "${ED}" -name '*.la' -delete || die
+}
