commit: df78c9d1581662e28dc12f0ecfd3d78c604c3b8e
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 3 05:17:33 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Jun 3 05:37:40 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=df78c9d1
dev-python/sphinx: Bump to 5.0.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/sphinx/Manifest | 1 +
dev-python/sphinx/sphinx-5.0.1.ebuild | 122 ++++++++++++++++++++++++++++++++++
2 files changed, 123 insertions(+)
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 8531236d67c4..eba82d499de6 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,2 +1,3 @@
DIST Sphinx-4.5.0.tar.gz 6698212 BLAKE2B
e6c46d35492c3d3068c4f97e497d33973ca86b40934578804fcec901fa89d2c52b45a7546b835b873846dd16936c1bd34a7b053aec8206c688d974671155fd56
SHA512
b44d2a81ed67adaefe16a07ae0cf053b5e6c775023aaa6c57d7b3950f171deac410e8004f787b151c3c2fc350650aa69a4dc2dc7239d1fd3d351e5194617cb2c
DIST Sphinx-5.0.0.tar.gz 6726986 BLAKE2B
95f2b85c7de6d900922730c3e431259e2333b3fe27e25cbe35e9584ccf1ac3442ca0949018e64ca8481e60f2298b46f6a77523a7a67e6aafe7492b62ff97aa70
SHA512
6b58427aa8a4d9e159f5b84366ab2193df5a9e940c9cb11b440dabd2c32dcdbadbb7eddbd9f6f8c53e577bf7bfb7c11f979835b5df75139b5c5315f88794871f
+DIST Sphinx-5.0.1.tar.gz 6728011 BLAKE2B
fe75d6bae6c035ee8ce24e3edb8ed8df9973835bdc935170775a7e80e1420bb0dee31976343dd0c3791508cc944f7b9ea44793569a94dc03756ab02d313e26d6
SHA512
6a850860fd7a320c49f2d406c511d1e7e2fc0e044911f98be3a07b1d519e79d57cd2d16c0042926255323625f186a26509772b425611fea85dfbeaae7e8e06c1
diff --git a/dev-python/sphinx/sphinx-5.0.1.ebuild
b/dev-python/sphinx/sphinx-5.0.1.ebuild
new file mode 100644
index 000000000000..64cbb666842a
--- /dev/null
+++ b/dev-python/sphinx/sphinx-5.0.1.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P^}
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+ https://www.sphinx-doc.org/
+ https://github.com/sphinx-doc/sphinx/
+ https://pypi.org/project/Sphinx/
+"
+SRC_URI="mirror://pypi/${MY_P::1}/${PN^}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos
~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+ <dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+ >=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+ <dev-python/docutils-0.19[${PYTHON_USEDEP}]
+ dev-python/imagesize[${PYTHON_USEDEP}]
+ >=dev-python/jinja-2.3[${PYTHON_USEDEP}]
+ >=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
+ >=dev-python/snowballstemmer-1.1[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/sphinxcontrib-serializinghtml-1.1.5[${PYTHON_USEDEP}]
+ dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+ dev-python/packaging[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/importlib_metadata-4.4[${PYTHON_USEDEP}]
+ ' 3.8 3.9)
+ latex? (
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ app-text/dvipng
+ )
+ !dev-python/namespace-sphinxcontrib
+"
+BDEPEND="
+ doc? (
+ dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+ media-gfx/graphviz
+ )
+ test? (
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ virtual/imagemagick-tools[jpeg,png,svg]
+ dev-texlive/texlive-fontsextra
+ dev-texlive/texlive-latexextra
+ dev-texlive/texlive-luatex
+ app-text/dvipng
+ )
+"
+
+PATCHES=(
+ "${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+ "${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ # disable internet access
+ sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+ doc/conf.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ esetup.py build_sphinx
+ HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+ fi
+}
+
+python_test() {
+ mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+ local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+ local EPYTEST_DESELECT=(
+ # these tests require Internet access
+ tests/test_build_latex.py::test_latex_images
+ tests/test_build_linkcheck.py::test_defaults
+ tests/test_build_linkcheck.py::test_defaults_json
+ tests/test_build_linkcheck.py::test_anchors_ignored
+ # TODO
+ tests/test_ext_autodoc_autoclass.py::test_classes
+ tests/test_ext_autodoc_autofunction.py::test_classes
+ )
+ [[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+ tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
+ tests/test_ext_autodoc.py::test_automethod_for_builtin
+ tests/test_ext_autodoc.py::test_cython
+ tests/test_ext_autodoc.py::test_partialfunction
+ tests/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+
tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+
tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+ tests/test_ext_autodoc_autofunction.py::test_builtin_function
+ tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
+
tests/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+
tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+
tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+ tests/test_util_inspect.py::test_isattributedescriptor
+ tests/test_util_typing.py::test_stringify_type_hints_pep_585
+ )
+
+ epytest
+}
