[gentoo-commits] repo/gentoo:master commit in: dev-python/django-cacheops/

[Michał Górny]

commit:     4b06a6aeb967336e9d4a7c91a11a2ee3003f1c88
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat May 28 04:50:49 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat May 28 05:00:16 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4b06a6ae

dev-python/django-cacheops: Bump to 6.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django-cacheops/Manifest                |  1 +
 .../django-cacheops/django-cacheops-6.1.ebuild     | 71 ++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-python/django-cacheops/Manifest 
b/dev-python/django-cacheops/Manifest
index aebea256451f..f0d6fb486eba 100644
--- a/dev-python/django-cacheops/Manifest
+++ b/dev-python/django-cacheops/Manifest
@@ -1 +1,2 @@
 DIST django-cacheops-6.0.tar.gz 70280 BLAKE2B 
9efe5a10d86f9ad25ad67701005de962185d2c491305bb56920203718c2d5fd0b28d43f2463e28c7c00c7592a78a3adea66090b398a205d5e361dfbcf90ae887
 SHA512 
54ecec62ff255a867b382bb1157117c8d14d7185891aacaae33ea11283beeae2fae60659621699a52f86d536b5a582d31f24f3b00f16c2e81c1a78ea4079504e
+DIST django-cacheops-6.1.gh.tar.gz 52972 BLAKE2B 
bdcd045912100ebdfdfd9add23b0df634b029cc2ffe41c351176e327f1e21c90457cfca9e45348dddce60e39fee5c431428ff7f2c954194e4c06c8bc09d78945
 SHA512 
43dcd4f302afee1acf73125aae7c2e2eece560cc6f07f3374391ac54e0438fd59b80a24e65f52bd7aa4978fd8a428939a8d607c7aa4b25f47d68373cfc12772f

diff --git a/dev-python/django-cacheops/django-cacheops-6.1.ebuild 
b/dev-python/django-cacheops/django-cacheops-6.1.ebuild
new file mode 100644
index 000000000000..9b7a1f421dc7
--- /dev/null
+++ b/dev-python/django-cacheops/django-cacheops-6.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="ORM cache with automatic granular event-driven invalidation for 
Django"
+HOMEPAGE="
+       https://github.com/Suor/django-cacheops/
+       https://pypi.org/project/django-cacheops/
+"
+SRC_URI="
+       https://github.com/Suor/django-cacheops/archive/${PV}.tar.gz
+               -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+       >=dev-python/django-1.8[${PYTHON_USEDEP}]
+       >=dev-python/redis-py-2.9.1[${PYTHON_USEDEP}]
+       >=dev-python/funcy-1.8[${PYTHON_USEDEP}]
+       >=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+       test? (
+               ${RDEPEND}
+               dev-db/redis
+               dev-python/dill[${PYTHON_USEDEP}]
+       )
+"
+
+src_prepare() {
+       # Remove test dependent on unpackaged before_after
+       sed -e 's/test_lock/_&/' -i tests/test_extras.py || die
+       distutils-r1_src_prepare
+}
+
+python_test() {
+       local -x DJANGO_SETTINGS_MODULE=tests.settings
+       local -x PYTHONPATH=.
+       django-admin test -v 2 || die
+}
+
+src_test() {
+       local redis_pid="${T}"/redis.pid
+       local redis_port=6379
+
+       einfo "Spawning Redis"
+       einfo "NOTE: Port ${redis_port} must be free"
+       "${EPREFIX}"/usr/sbin/redis-server - <<-EOF || die
+               daemonize yes
+               pidfile ${redis_pid}
+               port ${redis_port}
+               bind 127.0.0.1
+       EOF
+
+       # Run the tests
+       distutils-r1_src_test
+
+       # Clean up afterwards
+       kill "$(<"${redis_pid}")" || die
+}