commit: f61659ecd2e5a4976c33df582b7457834ab15e91
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat May 21 13:25:27 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat May 21 13:49:11 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f61659ec
dev-python/pyperclip: Use PEP517 build
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pyperclip/pyperclip-1.8.2-r1.ebuild | 65 ++++++++++++++++++++++++++
1 file changed, 65 insertions(+)
diff --git a/dev-python/pyperclip/pyperclip-1.8.2-r1.ebuild
b/dev-python/pyperclip/pyperclip-1.8.2-r1.ebuild
new file mode 100644
index 000000000000..6671b2930d46
--- /dev/null
+++ b/dev-python/pyperclip/pyperclip-1.8.2-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="A cross-platform clipboard module for Python"
+HOMEPAGE="
+ https://github.com/asweigart/pyperclip/
+ https://pypi.org/project/pyperclip/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc64 ~riscv ~s390
~sparc ~x86"
+
+RDEPEND="
+ || (
+ (
+ x11-misc/xsel
+ sys-apps/which
+ )
+ (
+ x11-misc/xclip
+ sys-apps/which
+ )
+ (
+ kde-plasma/plasma-workspace
+ sys-apps/which
+ )
+ dev-python/PyQt5[${PYTHON_USEDEP}]
+ dev-python/QtPy[${PYTHON_USEDEP}]
+ )
+"
+# test at least one backend
+BDEPEND="
+ test? (
+ ${RDEPEND}
+ )
+"
+
+src_prepare() {
+ # stupid windows
+ find -type f -exec sed -i -e 's:\r$::' {} + || die
+ # klipper is hard to get working, and once we make it work,
+ # it breaks most of the other backends
+ # wl-copy requires wayland, not Xvfb
+ sed -e 's:_executable_exists("\(klipper\|wl-copy\)"):False:' \
+ -i tests/test_pyperclip.py || die
+ distutils-r1_src_prepare
+}
+
+python_test() {
+ "${EPYTHON}" tests/test_pyperclip.py -vv ||
+ die "Tests fail on ${EPYTHON}"
+}
+
+src_test() {
+ virtx distutils-r1_src_test
+}
