commit: ec9df9fa3c0f9739bf740f905727c800743da6c3
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri May 20 07:47:09 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri May 20 08:29:25 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ec9df9fa
dev-python/pydantic: Bump to 1.9.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pydantic/Manifest | 1 +
dev-python/pydantic/pydantic-1.9.1.ebuild | 77 +++++++++++++++++++++++++++++++
2 files changed, 78 insertions(+)
diff --git a/dev-python/pydantic/Manifest b/dev-python/pydantic/Manifest
index daf4c35e9856..c0e76d2d2e62 100644
--- a/dev-python/pydantic/Manifest
+++ b/dev-python/pydantic/Manifest
@@ -1 +1,2 @@
DIST pydantic-1.9.0.tar.gz 299758 BLAKE2B
f6c2b89e598fc94db74b8165c449c752f11166752b12bbd37c23902b74c1f895bbd49b8fc4dc8da86b10880ac2e37178275cc28a42964e1133397364ea268d02
SHA512
ace542ff12698d568f2bea6121afc889c51892042b1a1b98464a6da6f71e50ecd8aafff7abd7ffd16983769844f7c970099d1fee7aa788f2e78172c0d5c4f472
+DIST pydantic-1.9.1.tar.gz 306846 BLAKE2B
c22e892f403b6ca5eff7f888c68f9df5c198fa03c8dab833edc556b3b1a4819fc28c9818a649bf5d9c4bb745b0bde826e164eda7760cd26f88e278c86776ad84
SHA512
19d2a50ef054b76cc7e8756759f3d67a14a58614dd6ff1b4f60e73354b0028e08743aa3bb5944da7ae357ab279134d3685c454d6affa6524b267c7cd9a40375e
diff --git a/dev-python/pydantic/pydantic-1.9.1.ebuild
b/dev-python/pydantic/pydantic-1.9.1.ebuild
new file mode 100644
index 000000000000..82f3a0b71858
--- /dev/null
+++ b/dev-python/pydantic/pydantic-1.9.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="https://github.com/samuelcolvin/pydantic";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390
~sparc ~x86"
+
+RDEPEND="
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/cython[${PYTHON_USEDEP}]
+ test? (
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ dev-python/python-dotenv[${PYTHON_USEDEP}]
+ >=dev-python/python-email-validator-1.2.1[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ sed -i -e '/CFLAGS/d' setup.py || die
+ distutils-r1_src_prepare
+}
+
+python_compile() {
+ if [[ ${EPYTHON} == pypy3 ]]; then
+ # do not build extensions on PyPy to workaround
+ # https://github.com/cython/cython/issues/4763
+ local -x SKIP_CYTHON=1
+ fi
+ distutils-r1_python_compile
+}
+
+python_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x PYTEST_PLUGINS=pytest_mock
+
+ local EPYTEST_DESELECT=(
+ # flaky test, known upstream
+
tests/test_hypothesis_plugin.py::test_can_construct_models_with_all_fields
+ )
+ case ${EPYTHON} in
+ python3.8)
+ EPYTEST_DESELECT+=(
+ # Those fail on python 3.8 as None changed
typing semantic on >=3.9
+ "tests/test_types.py::test_none[value_type3]"
+ tests/test_typing.py::test_is_none_type
+ )
+ ;;
+ pypy3)
+ EPYTEST_DESELECT+=(
+
tests/test_dataclasses.py::test_self_reference_dataclass
+
tests/test_private_attributes.py::test_private_attribute
+
tests/test_private_attributes.py::test_private_attribute_annotation
+
tests/test_private_attributes.py::test_private_attribute_factory
+
tests/test_private_attributes.py::test_private_attribute_multiple_inheritance
+
tests/test_private_attributes.py::test_underscore_attrs_are_private
+ )
+ ;;
+ esac
+ rm -rf pydantic || die
+ epytest
+}
