commit: d08b2af5d8cd2f9d6afadeb01d9c2d57c7ef420a
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu May 12 13:23:42 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu May 12 13:36:23 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d08b2af5
dev-python/automat: EAPI 8, PEP517
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/automat/automat-20.2.0-r1.ebuild | 54 +++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
diff --git a/dev-python/automat/automat-20.2.0-r1.ebuild
b/dev-python/automat/automat-20.2.0-r1.ebuild
new file mode 100644
index 000000000000..d7ad5e62e710
--- /dev/null
+++ b/dev-python/automat/automat-20.2.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P^}
+DESCRIPTION="Self-service finite-state machines for the programmer on the go"
+HOMEPAGE="https://github.com/glyph/automat https://pypi.org/project/Automat/";
+SRC_URI="mirror://pypi/${MY_P::1}/${PN^}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="examples"
+
+RDEPEND="
+ >=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+ "${FILESDIR}/automat-0.8.0-no-setup-py-m2r-import.patch"
+ "${FILESDIR}/test_visualize-twisted-import-errors.patch"
+)
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+ benchmark
+)
+
+python_install_all() {
+ if use examples; then
+ docinto examples
+ dodoc docs/examples/*.py
+ fi
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ einfo "For additional visualization functionality install both these
optional dependencies"
+ einfo " >=dev-python/twisted-16.1.1"
+ einfo " media-gfx/graphviz[python]"
+}
