commit: d9329d6ae1497543135054fc0a4ccb4daab48f33
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May 11 08:27:27 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May 11 08:42:35 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d9329d6a
dev-python/brotlicffi: Use PEP517 build
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/brotlicffi/brotlicffi-1.0.9.2-r1.ebuild | 65 ++++++++++++++++++++++
1 file changed, 65 insertions(+)
diff --git a/dev-python/brotlicffi/brotlicffi-1.0.9.2-r1.ebuild
b/dev-python/brotlicffi/brotlicffi-1.0.9.2-r1.ebuild
new file mode 100644
index 000000000000..40c949721164
--- /dev/null
+++ b/dev-python/brotlicffi/brotlicffi-1.0.9.2-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+# Commit of the Brotli library bundled within brotlipy.
+BROTLI_BUNDLED_COMMIT="46c1a881b41bb638c76247558aa04b1591af3aa7"
+
+DESCRIPTION="Python binding to the Brotli library"
+HOMEPAGE="
+ https://github.com/python-hyper/brotlicffi/
+ https://pypi.org/project/brotlicffi/
+"
+SRC_URI="
+ https://github.com/python-hyper/${PN}/archive/v${PV}.tar.gz
+ -> ${P}.gh.tar.gz
+ test? (
+
https://github.com/google/brotli/archive/${BROTLI_BUNDLED_COMMIT}.tar.gz
+ -> brotli-${BROTLI_BUNDLED_COMMIT}.tar.gz
+ )
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64
~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~ppc-macos ~x64-macos
~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+ app-arch/brotli:=
+ $(python_gen_cond_dep '
+ dev-python/cffi[${PYTHON_USEDEP}]
+ ' 'python*')
+"
+DEPEND="
+ test? (
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+ # incompatible with USE_SHARED_BROTLI=1
+ test/test_compatibility.py::test_brotli_version
+)
+
+src_unpack() {
+ default
+ if use test; then
+ mv "brotli-${BROTLI_BUNDLED_COMMIT}"/tests "${S}"/libbrotli/ ||
die
+ fi
+}
+
+src_configure() {
+ export USE_SHARED_BROTLI=1
+}
+
+python_test() {
+ epytest test
+}
