commit: c817ceb0600fdc5e3177d81243e875f617ca87b0
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon May 9 09:52:16 2022 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon May 9 21:55:17 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c817ceb0
app-office/libalkimia: 8.1.1 version bump
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
app-office/libalkimia/Manifest | 1 +
app-office/libalkimia/libalkimia-8.1.1.ebuild | 78 +++++++++++++++++++++++++++
2 files changed, 79 insertions(+)
diff --git a/app-office/libalkimia/Manifest b/app-office/libalkimia/Manifest
index 3ab2e8e0872e..b5e3cb146a78 100644
--- a/app-office/libalkimia/Manifest
+++ b/app-office/libalkimia/Manifest
@@ -1 +1,2 @@
DIST alkimia-8.1.0.tar.xz 230804 BLAKE2B
9cc005f8550181b4bf5dd945ac22592d711f0e9689758d56c62272d4879181f73faeaebecab24d74a790f6c6d1a59c42295ceb2c23d09195a76f7e6b6b4e53c0
SHA512
c3d0851ec6e5af7f690059f2c80942bbe69c6bde946898ba4a124c344dd47e0fba4e6ed0a5320e36385c060c49d5eeaaca35bc0a41410ef4ad849a4f9541d4d3
+DIST alkimia-8.1.1.tar.xz 252332 BLAKE2B
35c5cbca47e993d0a771ec723fcdd764265b2d0706a77ac06bb892b0717f791bfbceb2611b64810abe9fb209ed065abae1545efa512009003a3626aa84940181
SHA512
3e96f5b32da3d8a7f23b3b0f0a0ba7923e472b972c06b35f918c7f00d1745fa747afb6b8fdc1d596b2c1d9757a8037de04a039047f47eb46383070721da05258
diff --git a/app-office/libalkimia/libalkimia-8.1.1.ebuild
b/app-office/libalkimia/libalkimia-8.1.1.ebuild
new file mode 100644
index 000000000000..5aafacb22423
--- /dev/null
+++ b/app-office/libalkimia/libalkimia-8.1.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+KDE_ORG_NAME="alkimia"
+KFMIN=5.82.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+
SRC_URI="mirror://kde/stable/${KDE_ORG_NAME}/${PV}/${KDE_ORG_NAME}-${PV}.tar.xz"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Library with common classes and functionality used by KDE finance
applications"
+HOMEPAGE="https://www.linux-apps.com/content/show.php/libalkimia?content=137323
+https://community.kde.org/Alkimia";
+
+LICENSE="LGPL-2.1"
+SLOT="0/8"
+IUSE="doc gmp plasma webengine"
+
+DEPEND="
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtdeclarative-${QTMIN}:5
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtnetwork-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=kde-frameworks/kcodecs-${KFMIN}:5
+ >=kde-frameworks/kcompletion-${KFMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/kiconthemes-${KFMIN}:5
+ >=kde-frameworks/kio-${KFMIN}:5
+ >=kde-frameworks/knewstuff-${KFMIN}:5
+ >=kde-frameworks/ktextwidgets-${KFMIN}:5
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+ >=kde-frameworks/kxmlgui-${KFMIN}:5
+ !gmp? ( sci-libs/mpir:=[cxx] )
+ gmp? ( dev-libs/gmp:0=[cxx(+)] )
+ plasma? (
+ >=kde-frameworks/kpackage-${KFMIN}:5
+ >=kde-frameworks/plasma-${KFMIN}:5
+ )
+ webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+ virtual/pkgconfig
+ doc? ( app-doc/doxygen )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-8.1.0-cmake.patch" )
+
+src_configure() {
+ local mycmakeargs=(
+ -DENABLE_FINANCEQUOTE=OFF
+ -DBUILD_TOOLS=ON
+ -DBUILD_WITH_WEBKIT=OFF
+ $(cmake_use_find_package doc Doxygen)
+ $(cmake_use_find_package !gmp MPIR)
+ -DBUILD_APPLETS=$(usex plasma)
+ -DBUILD_WITH_WEBENGINE=$(usex webengine)
+ )
+ ecm_src_configure
+}
+
+src_test() {
+ # Depends on BUILD_WITH_WEBKIT, bug 736128
+ local myctestargs=(
+ -E "(alkonlinequotestest)"
+ )
+ ecm_src_test
+}
