commit: 5f7acbfd50e9808c1461313e00c40c8b8a35c1bb
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 9 20:15:35 2022 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Apr 9 20:23:21 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5f7acbfd
dev-python/zope-schema: PEP517, remove namespace dep
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/zope-schema/zope-schema-6.2.0-r1.ebuild | 58 ++++++++++++++++++++++
dev-python/zope-schema/zope-schema-6.2.0.ebuild | 43 ----------------
2 files changed, 58 insertions(+), 43 deletions(-)
diff --git a/dev-python/zope-schema/zope-schema-6.2.0-r1.ebuild
b/dev-python/zope-schema/zope-schema-6.2.0-r1.ebuild
new file mode 100644
index 000000000000..cbd811826980
--- /dev/null
+++ b/dev-python/zope-schema/zope-schema-6.2.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Zope schema Architecture"
+HOMEPAGE="
+ https://pypi.org/project/zope.schema/
+ https://github.com/zopefoundation/zope.schema/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+ dev-python/zope-event[${PYTHON_USEDEP}]
+ >=dev-python/zope-interface-5.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/zope-i18nmessageid[${PYTHON_USEDEP}]
+ dev-python/zope-testing[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+ # strip rdep specific to namespaces
+ sed -i -e "/'setuptools'/d" setup.py || die
+ distutils-r1_src_prepare
+}
+
+python_compile() {
+ distutils-r1_python_compile
+ find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+ cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+ # this is needed to keep the tests working while
+ # dev-python/namespace-zope is still installed
+ cat > zope/__init__.py <<-EOF || die
+ __path__ = __import__('pkgutil').extend_path(__path__, __name__)
+ EOF
+ eunittest
+ rm zope/__init__.py || die
+}
diff --git a/dev-python/zope-schema/zope-schema-6.2.0.ebuild
b/dev-python/zope-schema/zope-schema-6.2.0.ebuild
deleted file mode 100644
index 4f5e20c9cfe1..000000000000
--- a/dev-python/zope-schema/zope-schema-6.2.0.ebuild
+++ /dev/null
@@ -1,43 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_SETUPTOOLS=rdepend
-PYTHON_COMPAT=( python3_{8..10} pypy3 )
-
-inherit distutils-r1
-
-MY_PN=${PN/-/.}
-MY_P=${MY_PN}-${PV}
-
-DESCRIPTION="Zope schema Architecture"
-HOMEPAGE="https://github.com/zopefoundation/zope.schema
http://docs.zope.org/zope.schema/";
-SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="ZPL"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
-
-RDEPEND="
- dev-python/zope-event[${PYTHON_USEDEP}]
- >=dev-python/zope-interface-5.0.0[${PYTHON_USEDEP}]"
-BDEPEND="
- test? (
- dev-python/zope-i18nmessageid[${PYTHON_USEDEP}]
- dev-python/zope-testing[${PYTHON_USEDEP}]
- )"
-
-distutils_enable_tests unittest
-
-python_test() {
- eunittest src
-}
-
-python_install_all() {
- distutils-r1_python_install_all
-
- # remove .pth files since dev-python/namespace-zope handles the ns
- find "${D}" -name '*.pth' -delete || die
-}
