[gentoo-commits] repo/gentoo:master commit in: dev-python/zope-event/

[Michał Górny]

commit:     bf5ff9897380d4b69428600fdce0138b1eaf4554
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Apr  9 19:05:26 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Apr  9 19:08:01 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bf5ff989

dev-python/zope-event: EAPI 8, PEP517, remove namespace dep

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/zope-event/zope-event-4.5.0-r2.ebuild | 47 ++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/dev-python/zope-event/zope-event-4.5.0-r2.ebuild 
b/dev-python/zope-event/zope-event-4.5.0-r2.ebuild
new file mode 100644
index 000000000000..578489805cb5
--- /dev/null
+++ b/dev-python/zope-event/zope-event-4.5.0-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Event publishing / dispatch, used by Zope Component Architecture"
+HOMEPAGE="
+       https://pypi.org/project/zope.event/
+       https://github.com/zopefoundation/zope.event/
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv 
~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris 
~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+       # strip rdep specific to namespaces
+       sed -i -e "/'setuptools'/d" setup.py || die
+       distutils-r1_src_prepare
+}
+
+python_compile() {
+       distutils-r1_python_compile
+       find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+       cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+       # this is needed to keep the tests working while
+       # dev-python/namespace-zope is still installed
+       cat > zope/__init__.py <<-EOF || die
+               __path__ = __import__('pkgutil').extend_path(__path__, __name__)
+       EOF
+       eunittest
+       rm zope/__init__.py || die
+}