commit: a3045b07e451738d566af36b38e96dbf76d8659c
Author: Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 5 04:39:08 2022 +0000
Commit: Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Sat Mar 5 04:40:58 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a3045b07
sci-mathematics/alectryon: new package; add 1.4.0
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>
sci-mathematics/alectryon/Manifest | 1 +
sci-mathematics/alectryon/alectryon-1.4.0.ebuild | 78 ++++++++++++++++++++++
.../alectryon/files/50alectryon-gentoo.el | 3 +
sci-mathematics/alectryon/metadata.xml | 23 +++++++
4 files changed, 105 insertions(+)
diff --git a/sci-mathematics/alectryon/Manifest
b/sci-mathematics/alectryon/Manifest
new file mode 100644
index 000000000000..77bdaf1a36dc
--- /dev/null
+++ b/sci-mathematics/alectryon/Manifest
@@ -0,0 +1 @@
+DIST alectryon-1.4.0.tar.gz 312436 BLAKE2B
7f1e58670fbba0b31a4e4bc6502dffa72931ae3495c38b53987406a05aac9d3d1a34d75c89b7b85a6122ee6a7ce30970f8cf3190a5916e416e56854313077d4c
SHA512
1310a04c8584147b38af8edb19cc95bd71043f5d00f55cbf4d5649dad9eede5bd01dba6fb23b85acf7cb9e9619fd01e5f83d8d37064f0b43f706589b9ec8aeef
diff --git a/sci-mathematics/alectryon/alectryon-1.4.0.ebuild
b/sci-mathematics/alectryon/alectryon-1.4.0.ebuild
new file mode 100644
index 000000000000..bdbf53a0c35b
--- /dev/null
+++ b/sci-mathematics/alectryon/alectryon-1.4.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit elisp-common distutils-r1
+
+DESCRIPTION="Toolkit for literate programming in Coq"
+HOMEPAGE="https://github.com/cpitclaudel/alectryon/";
+
+if [[ "${PV}" == *9999* ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/cpitclaudel/${PN}.git";
+else
+ SRC_URI="https://github.com/cpitclaudel/${PN}/archive/v${PV}.tar.gz
+ -> ${P}.tar.gz"
+ KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc emacs"
+
+RDEPEND="
+ dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+ dev-python/docutils[${PYTHON_USEDEP}]
+ dev-python/dominate[${PYTHON_USEDEP}]
+ dev-python/myst_parser[${PYTHON_USEDEP}]
+ dev-python/pygments[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ sci-mathematics/coq-serapi
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ emacs? (
+ >=app-editors/emacs-23.1:*
+ app-emacs/flycheck
+ app-emacs/proofgeneral
+ )
+"
+
+DOCS=( CHANGES.rst CITATION.bib README.rst )
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+ python_foreach_impl distutils-r1_python_compile
+
+ use doc && emake -C ./recipes/sphinx latexpdf
+ use emacs && elisp-compile ./etc/elisp/alectryon.el
+}
+
+src_install() {
+ python_foreach_impl distutils-r1_python_install
+ einstalldocs
+
+ if use doc ; then
+ docinto html
+ dodoc ./recipes/sphinx/_build/html/*
+ docinto pdf
+ dodoc ./recipes/sphinx/_build/latex/alectryon-demo.pdf
+ docinto latex
+ dodoc ./recipes/sphinx/_build/latex/alectryon-demo.tex
+ fi
+ if use emacs ; then
+ elisp-install ${PN} ./etc/elisp/${PN}.el{,c}
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ fi
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
diff --git a/sci-mathematics/alectryon/files/50alectryon-gentoo.el
b/sci-mathematics/alectryon/files/50alectryon-gentoo.el
new file mode 100644
index 000000000000..2d6ca63cdd6d
--- /dev/null
+++ b/sci-mathematics/alectryon/files/50alectryon-gentoo.el
@@ -0,0 +1,3 @@
+(add-to-list 'load-path "@SITELISP@")
+(autoload 'alectryon-mode "alectryon" "Mode for Literate Coq files." t)
+(add-hook 'coq-mode-hook #'alectryon-mode t)
diff --git a/sci-mathematics/alectryon/metadata.xml
b/sci-mathematics/alectryon/metadata.xml
new file mode 100644
index 000000000000..67c427e81f35
--- /dev/null
+++ b/sci-mathematics/alectryon/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd";>
+
+<pkgmetadata>
+ <maintainer type="project">
+ <email>[email protected]</email>
+ <name>Gentoo Mathematics Project</name>
+ </maintainer>
+ <longdescription>
+ A library to process Coq and Lean snippets embedded in text documents,
+ showing goals and messages for each input sentence. Also a literate
+ programming toolkit. The goal of Alectryon is to make it easy to write
+ textbooks, blog posts, and other documents that mix interactive proofs and
+ prose.
+ Alectryon originally supported Coq only. Support for Lean is preliminary
+ and restricted to Lean 3.
+ </longdescription>
+ <upstream>
+ <changelog>https://github.com/cpitclaudel/alectryon/releases/</changelog>
+ <bugs-to>https://github.com/cpitclaudel/alectryon/issues/</bugs-to>
+ <remote-id type="github">cpitclaudel/alectryon</remote-id>
+ </upstream>
+</pkgmetadata>
