[gentoo-commits] repo/gentoo:master commit in: dev-libs/libclc/

[Michał Górny]

commit:     b34839c133f69c0f6f8f9f4beef3e1dea5dc1805
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Feb  6 15:16:52 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Feb  6 15:34:30 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b34839c1

dev-libs/libclc: Add 15.x live ebuild

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-libs/libclc/libclc-15.0.0.9999.ebuild | 68 +++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

diff --git a/dev-libs/libclc/libclc-15.0.0.9999.ebuild 
b/dev-libs/libclc/libclc-15.0.0.9999.ebuild
new file mode 100644
index 000000000000..36da442fa39d
--- /dev/null
+++ b/dev-libs/libclc/libclc-15.0.0.9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake llvm llvm.org python-any-r1
+
+DESCRIPTION="OpenCL C library"
+HOMEPAGE="https://libclc.llvm.org/";
+
+LICENSE="Apache-2.0-with-LLVM-exceptions || ( MIT BSD )"
+SLOT="0"
+KEYWORDS=""
+IUSE_VIDEO_CARDS="video_cards_nvidia video_cards_r600 video_cards_radeonsi"
+IUSE="${IUSE_VIDEO_CARDS}"
+REQUIRED_USE="|| ( ${IUSE_VIDEO_CARDS} )"
+
+LLVM_MAX_SLOT=14
+BDEPEND="
+       || (
+               sys-devel/clang:14
+               sys-devel/clang:13
+               sys-devel/clang:12
+               sys-devel/clang:11
+               sys-devel/clang:10
+       )
+       ${PYTHON_DEPS}"
+
+LLVM_COMPONENTS=( libclc )
+llvm.org_set_globals
+
+llvm_check_deps() {
+       has_version -b "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+       # we do not need llvm_pkg_setup
+       python-any-r1_pkg_setup
+}
+
+src_configure() {
+       local libclc_targets=()
+
+       use video_cards_nvidia && libclc_targets+=(
+               "nvptx--"
+               "nvptx64--"
+               "nvptx--nvidiacl"
+               "nvptx64--nvidiacl"
+       )
+       use video_cards_r600 && libclc_targets+=(
+               "r600--"
+       )
+       use video_cards_radeonsi && libclc_targets+=(
+               "amdgcn--"
+               "amdgcn-mesa-mesa3d"
+               "amdgcn--amdhsa"
+       )
+       # TODO: spirv
+       [[ ${#libclc_targets[@]} ]] || die "libclc target missing!"
+
+       libclc_targets=${libclc_targets[*]}
+       local mycmakeargs=(
+               -DLIBCLC_TARGETS_TO_BUILD="${libclc_targets// /;}"
+               -DLLVM_CONFIG="$(get_llvm_prefix 
"${LLVM_MAX_SLOT}")/bin/llvm-config"
+       )
+       cmake_src_configure
+}