[gentoo-commits] repo/gentoo:master commit in: dev-python/jaraco-context/

[Michał Górny]

commit:     2d1c86a2807c9b92bf343c82f78fbf4f45619113
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Feb  3 10:12:17 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Feb  3 10:58:14 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2d1c86a2

dev-python/jaraco-context: Use flit to build (for bootstrap)

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../jaraco-context/jaraco-context-4.1.1-r1.ebuild  | 37 ++++++++++++++++++++++
 1 file changed, 37 insertions(+)

diff --git a/dev-python/jaraco-context/jaraco-context-4.1.1-r1.ebuild 
b/dev-python/jaraco-context/jaraco-context-4.1.1-r1.ebuild
new file mode 100644
index 000000000000..caff446d88cb
--- /dev/null
+++ b/dev-python/jaraco-context/jaraco-context-4.1.1-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Context managers by jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.context";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN/-/.}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~x86"
+
+distutils_enable_tests pytest
+
+src_configure() {
+       grep -q 'build-backend = "setuptools' pyproject.toml ||
+               die "Upstream changed build-backend, recheck"
+       # write a custom pyproject.toml to ease setuptools bootstrap
+       cat > pyproject.toml <<-EOF || die
+               [build-system]
+               requires = ["flit_core >=3.2,<4"]
+               build-backend = "flit_core.buildapi"
+
+               [project]
+               name = "jaraco.context"
+               version = "${PV}"
+               description = "Context managers by jaraco"
+       EOF
+}