[gentoo-commits] repo/gentoo:master commit in: dev-python/jaraco-text/

[Michał Górny]

commit:     e5cf9a81354f614613641bfda1242e4426aa1f51
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Feb  3 10:21:45 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Feb  3 10:58:17 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e5cf9a81

dev-python/jaraco-text: Use flit to build (for bootstrap)

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/jaraco-text/jaraco-text-3.7.0-r1.ebuild | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)

diff --git a/dev-python/jaraco-text/jaraco-text-3.7.0-r1.ebuild 
b/dev-python/jaraco-text/jaraco-text-3.7.0-r1.ebuild
new file mode 100644
index 000000000000..f78beb6e0199
--- /dev/null
+++ b/dev-python/jaraco-text/jaraco-text-3.7.0-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Text utilities used by other projects by developer jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.text";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN/-/.}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+       >=dev-python/jaraco-context-4.1[${PYTHON_USEDEP}]
+       dev-python/jaraco-functools[${PYTHON_USEDEP}]
+       $(python_gen_cond_dep 
'dev-python/importlib_resources[${PYTHON_USEDEP}]' python3_8 pypy3)
+"
+
+distutils_enable_sphinx docs \
+       ">=dev-python/jaraco-packaging-3.2" \
+       ">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
+
+src_configure() {
+       grep -q 'build-backend = "setuptools' pyproject.toml ||
+               die "Upstream changed build-backend, recheck"
+       # write a custom pyproject.toml to ease setuptools bootstrap
+       cat > pyproject.toml <<-EOF || die
+               [build-system]
+               requires = ["flit_core >=3.2,<4"]
+               build-backend = "flit_core.buildapi"
+
+               [project]
+               name = "jaraco.text"
+               version = "${PV}"
+               description = "Module for text manipulation"
+       EOF
+}