commit: 8ebfcff7a0daccccaf7b999a3c7cc1745471cf45
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 29 00:22:08 2021 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Nov 29 00:22:32 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8ebfcff7
sys-kernel/gentoo-kernel-bin: add 5.4.162-r1 for arm64
Signed-off-by: Sam James <sam <AT> gentoo.org>
sys-kernel/gentoo-kernel-bin/Manifest | 1 +
.../gentoo-kernel-bin-5.4.162-r1.ebuild | 113 +++++++++++++++++++++
2 files changed, 114 insertions(+)
diff --git a/sys-kernel/gentoo-kernel-bin/Manifest
b/sys-kernel/gentoo-kernel-bin/Manifest
index 0180088d64a3..fe778660e7eb 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -62,6 +62,7 @@ DIST gentoo-kernel-5.4.161-1.amd64.xpak 61397959 BLAKE2B
9b213988ec360726a154c85
DIST gentoo-kernel-5.4.161-1.arm64.xpak 57696274 BLAKE2B
e2c6edf9cec49fe7715b5a2f92266367a64af9be9aa5f25fcdda1ac69f2ba3bbb19c6b45420d3a39053ddd5d1bc9aa30c079c5c8a87f5ce62b12ffe889238721
SHA512
a4bfcbb83267e78f6e52fca130fc3e0aacbedca6b91594d22d083431c4cf92b0fb8e2f85647438c7f1bc94cc0253f9c9f6e3cffbadfc99aeec5fe9aac177a1fe
DIST gentoo-kernel-5.4.161-1.x86.xpak 53165081 BLAKE2B
9bc7c8f2fe7754630edbf9f6df30912e435d9118395b529d732c12b1b1549815810df2e0714476bd4e545311b2c474b9258ebfe293b20dda338e92e3feb3e5ef
SHA512
9e1d201483befe38604bbb06ffb5a27da4a643a648bb7d732470007eddde22766f9934cdb2a3bee81d5bfe213d13c7f776708ce8a5b7900b5a4e3f2431c9cd59
DIST gentoo-kernel-5.4.162-1.amd64.xpak 61399544 BLAKE2B
45083bfa44957a5c0d54cd8e0633fb0ef59b403015071c58a3dc214cd2bd02744ff30d5dfb99d884d74aaa17183c93df96d56618902f69350b52dc08f4f5ae8b
SHA512
f12044d63e5191229252f007d023ca6722c3926ded98bf3a219bd61d44a6dadea02dbd2d2c56206f04a526d8a471b0c0a34a11dfd5788a79449c13635cf14003
+DIST gentoo-kernel-5.4.162-1.arm64.xpak 57697790 BLAKE2B
1b7adb38fc400ac386f3a748109df6132111b27f6b3e1f37f7a7d17bc3f50958503d38fd06c0c556b964478fd5e27e80ae7d8ebe003f0b161bc6644a0dcf6c49
SHA512
1451ecc61d771ae7dd148153ee06625cd1c4a1d559bb26908f5ab79ec78b7ebd47f5a134ceae845848713e46981dd0df9496fb514030194424a84a0f147a5460
DIST gentoo-kernel-5.4.162-1.x86.xpak 53220282 BLAKE2B
de783135d68ccd12a3f15aaa33c3905135ece4560bb089691f907df9e091fd00ef34f1e6be805d6a58f7fa25edc905bcb29c196d802b1d05069a3bcaf4b29ab5
SHA512
421a96c49eb997157475d6cc030e27316f42f909605a4ce0d705c95daf5a348d9bacb102b77be4817c5f988c01c29a4b5b04addce7305d9688b33933ca607b1c
DIST linux-5.10.tar.xz 116606704 BLAKE2B
b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1
SHA512
95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
DIST linux-5.13.tar.xz 119297284 BLAKE2B
9c4c12e2394dec064adff51f7ccdf389192eb27ba7906db5eda543afe3d04afca6b9ea0848a057571bf2534eeb98e1e3a67734deff82c0d3731be205ad995668
SHA512
a8edf97e9d38a49f1be2bde1e29ad96274bb2c6f7e8a2bebaa1161dd4df9cabcbaec4ff644c45bee94f86ae47725087d6deed0cd954209cec717621d137db85e
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.162-r1.ebuild
b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.162-r1.ebuild
new file mode 100644
index 000000000000..fe6e6023d323
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.162-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/";
+SRC_URI+="
+ https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+
https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+
https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+ arm64? (
+
https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+ -> ${BINPKG}.arm64.xpak
+ )"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+ !sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+ >=virtual/dist-kernel-${PV}"
+BDEPEND="
+ sys-devel/bc
+ sys-devel/flex
+ virtual/libelf
+ virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+ default
+ ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+ tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+ eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+ local PATCHES=(
+ # meh, genpatches have no directory
+ "${WORKDIR}"/*.patch
+ )
+ cd "${MY_P}" || die
+ default
+}
+
+src_configure() {
+ # force ld.bfd if we can find it easily
+ local LD="$(tc-getLD)"
+ if type -P "${LD}.bfd" &>/dev/null; then
+ LD+=.bfd
+ fi
+
+ tc-export_build_env
+ local makeargs=(
+ V=1
+
+ HOSTCC="$(tc-getBUILD_CC)"
+ HOSTCXX="$(tc-getBUILD_CXX)"
+ HOSTCFLAGS="${BUILD_CFLAGS}"
+ HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+ CROSS_COMPILE=${CHOST}-
+ AS="$(tc-getAS)"
+ CC="$(tc-getCC)"
+ LD="${LD}"
+ AR="$(tc-getAR)"
+ NM="$(tc-getNM)"
+ STRIP=":"
+ OBJCOPY="$(tc-getOBJCOPY)"
+ OBJDUMP="$(tc-getOBJDUMP)"
+
+ # we need to pass it to override colliding Gentoo envvar
+ ARCH=$(tc-arch-kernel)
+
+ O="${WORKDIR}"/modprep
+ )
+
+ mkdir modprep || die
+ cp "usr/src/linux-${KPV}/.config" modprep/ || die
+ emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+ kernel-install_test "${KPV}" \
+ "${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)"
\
+ "lib/modules/${KPV}"
+}
+
+src_install() {
+ mv lib usr "${ED}"/ || die
+
+ # strip out-of-source build stuffs from modprep
+ # and then copy built files
+ find modprep -type f '(' \
+ -name Makefile -o \
+ -name '*.[ao]' -o \
+ '(' -name '.*' -a -not -name '.config' ')' \
+ ')' -delete || die
+ rm modprep/source || die
+ cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}
