commit: 513d6cf7957e630a558c6bb79beb2cdd5aa9fa5b
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 30 18:11:36 2021 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Jul 30 18:15:10 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=513d6cf7
sys-fs/btrfs-progs: Bump to version 5.13.1
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
sys-fs/btrfs-progs/Manifest | 1 +
sys-fs/btrfs-progs/btrfs-progs-5.13.1.ebuild | 130 +++++++++++++++++++++++++++
2 files changed, 131 insertions(+)
diff --git a/sys-fs/btrfs-progs/Manifest b/sys-fs/btrfs-progs/Manifest
index 8530848c265..1d260b1b9e1 100644
--- a/sys-fs/btrfs-progs/Manifest
+++ b/sys-fs/btrfs-progs/Manifest
@@ -1,3 +1,4 @@
DIST btrfs-progs-v5.10.1.tar.xz 2204164 BLAKE2B
ed83729754f9abd22d4d2e7ae9a7e90e80be9b63d49a4a9692e20e5939467dbd864834b71495661e1c7a1fca89e253a62fbda37f1d01d2eadecb13f5904f0dd0
SHA512
32e5b8bda1863e34613802db91946f240b2cde21288ff8f95c1807e7afd0a67c5a704aa4d2bc0d7b1ca094de6831adbfec83fe61f74e1caf6d1975be7d972f2d
DIST btrfs-progs-v5.12.1.tar.xz 2220424 BLAKE2B
1e6120609feb37dd2ced04b27d8cba9a28c3b962add6f037927dcb05bdcd46a229f981f7f68231ee58e7e36a65fae4e6041e92c0db11dba56fe63b09bca30cc7
SHA512
a4044ad7e40e232442601f102ea1c64a65aa4d9765be303813d2547a5b730c5f2f84c9b9c652a4218ab16821fdd049dd8573a1f7f6cc27974c2c4389243e20f5
+DIST btrfs-progs-v5.13.1.tar.xz 2237108 BLAKE2B
6de5d70d1b3611dc7c502530c08f9b58da798b33a97a415a787c5ed55b3369432f362c4d61636b6c85d952bf4482125a2d59397214ac543cf7160de28fe20a0b
SHA512
4ef8256da59614d17316db9c19909a2aa4f0557504201e421332c63a4935dbd6578791484b9f3f2dbeaaa28f6f4b4fd59c5a7adf6853fd76546ac213a0f09823
DIST btrfs-progs-v5.13.tar.xz 2234256 BLAKE2B
dd6dc6977c2a21471b59573c3ae6f7853d5ec4434549873174a6bde6b3ed4c5ed03c5adaed896538cb74699f538ec13403c193f132fcc8a2ba1b4f6bbdbac67e
SHA512
7832ca02b77410edd8d80f10c6f1482dee944073518dbacd5773e70f27b7c632231ea66bdb64aa4611869465c15d2d60d364bfd25c2e40e0a2c198edbf9741cd
diff --git a/sys-fs/btrfs-progs/btrfs-progs-5.13.1.ebuild
b/sys-fs/btrfs-progs/btrfs-progs-5.13.1.ebuild
new file mode 100644
index 00000000000..10909cb0c94
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-5.13.1.ebuild
@@ -0,0 +1,130 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit bash-completion-r1 python-single-r1
+
+libbtrfs_soname=0
+
+if [[ ${PV} != 9999 ]]; then
+ MY_PV="v${PV/_/-}"
+ [[ "${PV}" = *_rc* ]] || \
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv
~sparc ~x86"
+
SRC_URI="https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${PN}-${MY_PV}.tar.xz";
+ S="${WORKDIR}/${PN}-${MY_PV}"
+else
+ WANT_LIBTOOL=none
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/kdave/btrfs-progs.git";
+ EGIT_BRANCH="devel"
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.wiki.kernel.org";
+
+LICENSE="GPL-2"
+SLOT="0/${libbtrfs_soname}"
+IUSE="+convert doc python reiserfs static static-libs +zstd"
+
+RESTRICT=test # tries to mount repared filesystems
+
+RDEPEND="
+ dev-libs/lzo:2=
+ sys-apps/util-linux:0=[static-libs(+)?]
+ sys-libs/zlib:0=
+ convert? (
+ sys-fs/e2fsprogs:0=
+ sys-libs/e2fsprogs-libs:0=
+ reiserfs? (
+ >=sys-fs/reiserfsprogs-3.6.27
+ )
+ )
+ python? ( ${PYTHON_DEPS} )
+ zstd? ( app-arch/zstd:0= )
+"
+DEPEND="${RDEPEND}
+ >=sys-kernel/linux-headers-5.10
+ convert? ( sys-apps/acl )
+ python? (
+ $(python_gen_cond_dep '
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ ')
+ )
+ static? (
+ dev-libs/lzo:2[static-libs(+)]
+ sys-apps/util-linux:0[static-libs(+)]
+ sys-libs/zlib:0[static-libs(+)]
+ convert? (
+ sys-fs/e2fsprogs:0[static-libs(+)]
+ sys-libs/e2fsprogs-libs:0[static-libs(+)]
+ reiserfs? (
+ >=sys-fs/reiserfsprogs-3.6.27[static-libs(+)]
+ )
+ )
+ zstd? ( app-arch/zstd:0[static-libs(+)] )
+ )
+"
+BDEPEND="
+ doc? (
+ || ( >=app-text/asciidoc-8.6.0 dev-ruby/asciidoctor )
+ app-text/docbook-xml-dtd:4.5
+ app-text/xmlto
+ )
+"
+
+if [[ ${PV} == 9999 ]]; then
+ DEPEND+=" sys-devel/gnuconfig"
+fi
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ if [[ ${PV} == 9999 ]]; then
+ AT_M4DIR=m4 eautoreconf
+ mkdir config || die
+ local automakedir="$(autotools_run_tool --at-output automake
--print-libdir)"
+ [[ -e ${automakedir} ]] || die "Could not locate automake
directory"
+ ln -s "${automakedir}"/install-sh config/install-sh || die
+ ln -s "${EPREFIX}"/usr/share/gnuconfig/config.guess
config/config.guess || die
+ ln -s "${EPREFIX}"/usr/share/gnuconfig/config.sub
config/config.sub || die
+ fi
+}
+
+src_configure() {
+ local myeconfargs=(
+ --bindir="${EPREFIX}"/sbin
+ $(use_enable convert)
+ $(use_enable doc documentation)
+ $(use_enable elibc_glibc backtrace)
+ $(use_enable python)
+ $(use_enable static-libs static)
+ $(use_enable zstd)
+ --with-convert=ext2$(usex reiserfs ',reiserfs' '')
+ )
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ emake V=1 all $(usev static)
+}
+
+src_install() {
+ local makeargs=(
+ $(usex python install_python '')
+ $(usex static install-static '')
+ )
+ emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
+ newbashcomp btrfs-completion btrfs
+ use python && python_optimize
+
+ # install prebuilt subset of manuals
+ use doc || doman Documentation/*.[58]
+}
