commit: e13a5a1b73e9f1a232370a086ed7c8fc0d60bdeb
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 13 15:42:07 2021 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Jul 13 15:43:50 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e13a5a1b
sys-fs/btrfs-progs: Bump to version 5.13
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
sys-fs/btrfs-progs/Manifest | 1 +
sys-fs/btrfs-progs/btrfs-progs-5.13.ebuild | 130 +++++++++++++++++++++++++++++
2 files changed, 131 insertions(+)
diff --git a/sys-fs/btrfs-progs/Manifest b/sys-fs/btrfs-progs/Manifest
index 5722c44bb2d..b9590e9e2ec 100644
--- a/sys-fs/btrfs-progs/Manifest
+++ b/sys-fs/btrfs-progs/Manifest
@@ -2,3 +2,4 @@ DIST btrfs-progs-v5.10.1.tar.xz 2204164 BLAKE2B
ed83729754f9abd22d4d2e7ae9a7e90e
DIST btrfs-progs-v5.11.1.tar.xz 2213548 BLAKE2B
f428e8ffb62f60e6772102f4623b9965edc5d18fa60aa8cb60fd92b4867ee29e3067a6b9d0935c738acce5f0abfc4b88c900121ee233aa881857ed4690e38e3b
SHA512
f93a54bd2256851a74fc8e52b26f697bd7bf788cb2481512c92ebf1b9a2f2968b62d680f9f000d6162bd6f22b5d632b2149a88adad8c489e1332f810b439da90
DIST btrfs-progs-v5.12.1.tar.xz 2220424 BLAKE2B
1e6120609feb37dd2ced04b27d8cba9a28c3b962add6f037927dcb05bdcd46a229f981f7f68231ee58e7e36a65fae4e6041e92c0db11dba56fe63b09bca30cc7
SHA512
a4044ad7e40e232442601f102ea1c64a65aa4d9765be303813d2547a5b730c5f2f84c9b9c652a4218ab16821fdd049dd8573a1f7f6cc27974c2c4389243e20f5
DIST btrfs-progs-v5.12.tar.xz 2220396 BLAKE2B
be3eaadca7386ab1348c4bef6cf10270a42ac34c8e7e1cb54b9db600fde6a5958cff9453e6c287fba23f928116eeccca5d90f78f9c042b972a3ac66a31566e3b
SHA512
af9ab8bf232e0c62cc093d848b95991924cc3a84020fb9c85765a63a1cc132403e784bf18f81b71b2af9daa0038a7b11e578ee7b50d90481a888f7a967a5b197
+DIST btrfs-progs-v5.13.tar.xz 2234256 BLAKE2B
dd6dc6977c2a21471b59573c3ae6f7853d5ec4434549873174a6bde6b3ed4c5ed03c5adaed896538cb74699f538ec13403c193f132fcc8a2ba1b4f6bbdbac67e
SHA512
7832ca02b77410edd8d80f10c6f1482dee944073518dbacd5773e70f27b7c632231ea66bdb64aa4611869465c15d2d60d364bfd25c2e40e0a2c198edbf9741cd
diff --git a/sys-fs/btrfs-progs/btrfs-progs-5.13.ebuild
b/sys-fs/btrfs-progs/btrfs-progs-5.13.ebuild
new file mode 100644
index 00000000000..90b1aa08f67
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-5.13.ebuild
@@ -0,0 +1,130 @@
+# Copyright 2008-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit bash-completion-r1 python-single-r1
+
+libbtrfs_soname=0
+
+if [[ ${PV} != 9999 ]]; then
+ MY_PV="v${PV/_/-}"
+ [[ "${PV}" = *_rc* ]] || \
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv
~sparc ~x86"
+
SRC_URI="https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${PN}-${MY_PV}.tar.xz";
+ S="${WORKDIR}/${PN}-${MY_PV}"
+else
+ WANT_LIBTOOL=none
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/kdave/btrfs-progs.git";
+ EGIT_BRANCH="devel"
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.wiki.kernel.org";
+
+LICENSE="GPL-2"
+SLOT="0/${libbtrfs_soname}"
+IUSE="+convert doc python reiserfs static static-libs +zstd"
+
+RESTRICT=test # tries to mount repared filesystems
+
+RDEPEND="
+ dev-libs/lzo:2=
+ sys-apps/util-linux:0=[static-libs(+)?]
+ sys-libs/zlib:0=
+ convert? (
+ sys-fs/e2fsprogs:0=
+ sys-libs/e2fsprogs-libs:0=
+ reiserfs? (
+ >=sys-fs/reiserfsprogs-3.6.27
+ )
+ )
+ python? ( ${PYTHON_DEPS} )
+ zstd? ( app-arch/zstd:0= )
+"
+DEPEND="${RDEPEND}
+ >=sys-kernel/linux-headers-5.10
+ convert? ( sys-apps/acl )
+ python? (
+ $(python_gen_cond_dep '
+ dev-python/setuptools[${PYTHON_MULTI_USEDEP}]
+ ')
+ )
+ static? (
+ dev-libs/lzo:2[static-libs(+)]
+ sys-apps/util-linux:0[static-libs(+)]
+ sys-libs/zlib:0[static-libs(+)]
+ convert? (
+ sys-fs/e2fsprogs:0[static-libs(+)]
+ sys-libs/e2fsprogs-libs:0[static-libs(+)]
+ reiserfs? (
+ >=sys-fs/reiserfsprogs-3.6.27[static-libs(+)]
+ )
+ )
+ zstd? ( app-arch/zstd:0[static-libs(+)] )
+ )
+"
+BDEPEND="
+ doc? (
+ || ( >=app-text/asciidoc-8.6.0 dev-ruby/asciidoctor )
+ app-text/docbook-xml-dtd:4.5
+ app-text/xmlto
+ )
+"
+
+if [[ ${PV} == 9999 ]]; then
+ DEPEND+=" sys-devel/gnuconfig"
+fi
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ if [[ ${PV} == 9999 ]]; then
+ AT_M4DIR=m4 eautoreconf
+ mkdir config || die
+ local automakedir="$(autotools_run_tool --at-output automake
--print-libdir)"
+ [[ -e ${automakedir} ]] || die "Could not locate automake
directory"
+ ln -s "${automakedir}"/install-sh config/install-sh || die
+ ln -s "${EPREFIX}"/usr/share/gnuconfig/config.guess
config/config.guess || die
+ ln -s "${EPREFIX}"/usr/share/gnuconfig/config.sub
config/config.sub || die
+ fi
+}
+
+src_configure() {
+ local myeconfargs=(
+ --bindir="${EPREFIX}"/sbin
+ $(use_enable convert)
+ $(use_enable doc documentation)
+ $(use_enable elibc_glibc backtrace)
+ $(use_enable python)
+ $(use_enable static-libs static)
+ $(use_enable zstd)
+ --with-convert=ext2$(usex reiserfs ',reiserfs' '')
+ )
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ emake V=1 all $(usev static)
+}
+
+src_install() {
+ local makeargs=(
+ $(usex python install_python '')
+ $(usex static install-static '')
+ )
+ emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
+ newbashcomp btrfs-completion btrfs
+ use python && python_optimize
+
+ # install prebuilt subset of manuals
+ use doc || doman Documentation/*.[58]
+}
