[gentoo-commits] repo/gentoo:master commit in: dev-python/PyQtWebEngine/

[Andrew Ammerlaan]

commit:     941761bdef4dc05d94c47f5597c23db16cd943f7
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Sat May 29 08:19:43 2021 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Tue Jun  1 17:07:08 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=941761bd

dev-python/PyQtWebEngine: add 5.15.4, add py3.10

Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/PyQtWebEngine/Manifest                  |  1 +
 .../PyQtWebEngine/PyQtWebEngine-5.15.4.ebuild      | 74 ++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-python/PyQtWebEngine/Manifest 
b/dev-python/PyQtWebEngine/Manifest
index 3f19129c434..e8c22cbea35 100644
--- a/dev-python/PyQtWebEngine/Manifest
+++ b/dev-python/PyQtWebEngine/Manifest
@@ -1 +1,2 @@
 DIST PyQtWebEngine-5.15.2.tar.gz 48608 BLAKE2B 
a03f77b0cde0d1031e8f1c4c6b5d13a342c28cf814ebaaf4a2cdb4608ce40cdd8163783932abc76cda583c0fed7191653b537598a9ab65f6509ef88008538e31
 SHA512 
7e6d95833b1a9e5bb5275eff01e1923419da35d13862fc4cbb231cbf950ed45e628bc7e161b0b6b66c718ee439a1a8e66dd754cee9adcdf69ab1b8ffab58901e
+DIST PyQtWebEngine-5.15.4.tar.gz 49022 BLAKE2B 
0ac0b3424f22aabbfd733f2a876e502f133c81f639fbd87a4c7509865635b29d4bd3596ccc151b0919a28eff0015913c4fae1a831dbe774fe2d2aeee732e469b
 SHA512 
25cf8578ffae8adbc1dd8d914921b4edf91f19fcf983c9c83c9c8934b4e918ba27bd34a6b9c8252773ec32e6f1f13a06f22cf7d7326a5aceaa91530ea4ee047e

diff --git a/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.4.ebuild 
b/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.4.ebuild
new file mode 100644
index 00000000000..5ba44ef3adf
--- /dev/null
+++ b/dev-python/PyQtWebEngine/PyQtWebEngine-5.15.4.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..10} )
+inherit python-r1 qmake-utils
+
+DESCRIPTION="Python bindings for QtWebEngine"
+HOMEPAGE="https://www.riverbankcomputing.com/software/pyqtwebengine/intro";
+
+MY_P=${PN}-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+       SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz";
+else
+       SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="debug"
+
+REQUIRED_USE="
+       ${PYTHON_REQUIRED_USE}
+"
+
+RDEPEND="
+       ${PYTHON_DEPS}
+       
>=dev-python/PyQt5-${PV}[gui,network,printsupport,ssl,webchannel,widgets,${PYTHON_USEDEP}]
+       >=dev-python/PyQt5-sip-4.19.22:=[${PYTHON_USEDEP}]
+       dev-qt/qtcore:5
+       dev-qt/qtwebengine:5[widgets]
+"
+DEPEND="${RDEPEND}
+       >=dev-python/sip-4.19.22[${PYTHON_USEDEP}]
+"
+
+src_configure() {
+       configuration() {
+               local myconf=(
+                       "${EPYTHON}"
+                       "${S}"/configure.py
+                       --qmake="$(qt5_get_bindir)"/qmake
+                       $(usex debug '--debug --trace' '')
+                       --verbose
+               )
+               echo "${myconf[@]}"
+               "${myconf[@]}" || die
+
+               # Fix parallel install failure
+               sed -i -e '/INSTALLS += distinfo/i distinfo.depends = 
install_subtargets install_pep484_stubs install_api' \
+                       ${PN}.pro || die
+
+               # Run eqmake to respect toolchain and build flags
+               eqmake5 -recursive ${PN}.pro
+       }
+       python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+       python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+       installation() {
+               emake INSTALL_ROOT="${D}" install
+               python_optimize
+       }
+       python_foreach_impl run_in_build_dir installation
+
+       einstalldocs
+}