[gentoo-commits] repo/gentoo:master commit in: dev-games/tiled/

[Michael Palimaka]

commit:     777b9ac31c0012e3802a7c2e1b41995b0d5e23f4
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Wed Apr  7 12:30:36 2021 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Wed Apr  7 12:30:47 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=777b9ac3

dev-games/tiled: version bump 1.5.0

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Michael Palimaka <kensington <AT> gentoo.org>

 dev-games/tiled/Manifest           |  1 +
 dev-games/tiled/tiled-1.5.0.ebuild | 72 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index 21fd980bacb..06ddb80e981 100644
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-1.4.3.tar.gz 17806808 BLAKE2B 
81b5a32cc1e6f5f3b4af5520752d34572f0e78aad90df435d075b53ac18b39961aa22d23cff614cd83f0883fd2fd2bca69026160cb8b1b727fddaeff5764babe
 SHA512 
1e75e323733e05563bf542364778d95f2f22484ec0d85b4a9e7fac782c117934b37b049724979be5c83de86a3900c7ca2e9f3c5a660c530d2ecd0f023eb22c2e
+DIST tiled-1.5.0.tar.gz 16694406 BLAKE2B 
ccab3ec9f5ac807126ddf5d26e4eaa06357e67ffbd63550bdad93e814ff02350f9138f62114a56b5e64bc6c7fd3f6664ab7da836cab7e478ea7075111fa1cae7
 SHA512 
eb25affdab481db29ab2bbaeb4abafd453b2b43ae47e4b8f9f2fd1ed0d8ed55fdb45ec1bdc0b484ba9a2d63afad5a0c9ba6376304ed4b1eab3918c36a0af29c9

diff --git a/dev-games/tiled/tiled-1.5.0.ebuild 
b/dev-games/tiled/tiled-1.5.0.ebuild
new file mode 100644
index 00000000000..fdbcb6753cd
--- /dev/null
+++ b/dev-games/tiled/tiled-1.5.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+inherit python-single-r1 qmake-utils xdg-utils
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="https://www.mapeditor.org/";
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz";
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+       app-arch/zstd:=
+       >=dev-qt/qtcore-5.15:5
+       >=dev-qt/qtdeclarative-5.15:5
+       >=dev-qt/qtgui-5.15:5
+       >=dev-qt/qtnetwork-5.15:5
+       >=dev-qt/qtwidgets-5.15:5
+       sys-libs/zlib
+       python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+       dev-qt/linguist-tools:5
+       virtual/pkgconfig
+"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+       eqmake5 \
+               LIBDIR="/usr/$(get_libdir)" \
+               PREFIX="/usr" \
+               SYSTEM_ZSTD="yes" \
+               DISABLE_PYTHON_PLUGIN="$(usex !python)" \
+               USE_FHS_PLUGIN_PATH="true"
+}
+
+src_install() {
+       emake INSTALL_ROOT="${D}" install
+
+       einstalldocs
+
+       if use examples ; then
+               docompress -x /usr/share/doc/${PF}/examples
+               dodoc -r examples
+       fi
+}
+
+pkg_postinst() {
+       xdg_icon_cache_update
+       xdg_desktop_database_update
+       xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+       xdg_icon_cache_update
+       xdg_desktop_database_update
+       xdg_mimeinfo_database_update
+}