[gentoo-commits] repo/gentoo:master commit in: games-rpg/coe2/

[Sam James]

commit:     19b9ca7f6e13e223304ac84c7e24f03619b990d3
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Apr  4 00:49:15 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Apr  4 06:32:35 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=19b9ca7f

games-rpg/coe2: port to EAPI 7, games.eclass--

Signed-off-by: Sam James <sam <AT> gentoo.org>

 .../{coe2-2007-r1.ebuild => coe2-2007-r2.ebuild}   | 46 +++++++++++++---------
 1 file changed, 27 insertions(+), 19 deletions(-)

diff --git a/games-rpg/coe2/coe2-2007-r1.ebuild 
b/games-rpg/coe2/coe2-2007-r2.ebuild
similarity index 55%
rename from games-rpg/coe2/coe2-2007-r1.ebuild
rename to games-rpg/coe2/coe2-2007-r2.ebuild
index 99a3f1b823f..3ac7358ce27 100644
--- a/games-rpg/coe2/coe2-2007-r1.ebuild
+++ b/games-rpg/coe2/coe2-2007-r2.ebuild
@@ -1,29 +1,33 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit eutils games
+EAPI=7
+
+inherit desktop wrapper
 
 DESCRIPTION="Precursor to the Dominions series"
 HOMEPAGE="https://www.shrapnelgames.com/Our_Games/Free_Games.html";
 SRC_URI="https://download.shrapnelgames.com/downloads/${PN}_${PV}.zip";
+S="${WORKDIR}"/coe
 
 LICENSE="all-rights-reserved"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-IUSE=""
 RESTRICT="mirror bindist"
 
-RDEPEND="media-libs/libsdl[sound,video]"
-DEPEND="${RDEPEND}
-       app-arch/unzip"
-
-S=${WORKDIR}/coe
+DEPEND="media-libs/libsdl[sound,video]"
+RDEPEND="
+       ${DEPEND}
+       acct-group/gamestat
+"
+BDEPEND="app-arch/unzip"
 
 # bug #430026
-QA_PREBUILT="${GAMES_PREFIX_OPT}/coe2/coe_linux"
+QA_PREBUILT="opt/coe2/coe_linux"
 
 src_prepare() {
+       default
+
        rm -r *.{dll,exe} old || die
        if use amd64 ; then
                mv -f coe_linux64bit coe_linux || die
@@ -31,25 +35,29 @@ src_prepare() {
 }
 
 src_install() {
-       insinto "${GAMES_PREFIX_OPT}/${PN}"
+       insinto /opt/${PN}
        doins *.{bgm,smp,trp,trs,wrl}
        dodoc history.txt manual.txt readme.txt
-       exeinto "${GAMES_PREFIX_OPT}/${PN}"
+       exeinto /opt/${PN}
        doexe coe_linux
 
-       games_make_wrapper ${PN} "./coe_linux" "${GAMES_PREFIX_OPT}/${PN}"
+       make_wrapper ${PN} "./coe_linux" "/opt/${PN}"
        make_desktop_entry ${PN} "Conquest of Elysium 2"
 
        # Slots for saved games.
        # The game shows e.g. "EMPTY SLOT 0?", but it works.
-       local f slot state_dir=${GAMES_STATEDIR}/${PN}
-       dodir "${state_dir}"
+       local state_dir=/var/lib/${PN}
+       dodir ${state_dir}
+
+       local f slot
        for slot in {0..4} ; do
                f=save${slot}
-               dosym "${state_dir}/save${slot}" 
"${GAMES_PREFIX_OPT}/${PN}/${f}"
-               echo "empty slot ${slot}" > "${D}${state_dir}/${f}" || die
-               fperms 660 "${state_dir}/${f}"
+
+               dosym ${state_dir}/save${slot} /opt/${PN}/${f}
+               echo "empty slot ${slot}" > "${ED}"/${state_dir}/${f} || die
+               fperms 660 ${state_dir}/${f}
        done
 
-       prepgamesdirs
+       fowners -R root:gamestat /var/lib/${PN}/
+       fperms g+s /opt/${PN}/coe_linux
 }