commit: f154b7a92f4208fb2404d16c802c3c7a4082bf99
Author: Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 23 16:50:05 2021 +0000
Commit: Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Wed Feb 24 00:02:49 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f154b7a9
dev-python/httpcore: new package, version 0.12.3
Indirect dependency of dev-python/denonavr.
Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>
dev-python/httpcore/Manifest | 1 +
dev-python/httpcore/httpcore-0.12.3.ebuild | 64 ++++++++++++++++++++++++++++++
dev-python/httpcore/metadata.xml | 13 ++++++
3 files changed, 78 insertions(+)
diff --git a/dev-python/httpcore/Manifest b/dev-python/httpcore/Manifest
new file mode 100644
index 00000000000..b7e7fb9d804
--- /dev/null
+++ b/dev-python/httpcore/Manifest
@@ -0,0 +1 @@
+DIST httpcore-0.12.3.tar.gz 57587 BLAKE2B
3c0e7a210b21e54564c4c6077fadf66344b887662c71b05a1ad4a2c0224a4d703eccdf576d4443341176edee03b6776bfd49aaef2ea2f29f02614677e1dfad85
SHA512
b31535231dc2b6a5f1c9c0c538628f75360f04b4747b447ab0a7168ed32d0eabd463335c2f7fa782dcabb4cbc32891a2839ae50e0999d5a791c01b02533d38f0
diff --git a/dev-python/httpcore/httpcore-0.12.3.ebuild
b/dev-python/httpcore/httpcore-0.12.3.ebuild
new file mode 100644
index 00000000000..9d5010440b8
--- /dev/null
+++ b/dev-python/httpcore/httpcore-0.12.3.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="A minimal low-level HTTP client"
+HOMEPAGE="https://www.encode.io/httpcore/";
+SRC_URI="https://github.com/encode/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+ =dev-python/h11-0*[${PYTHON_USEDEP}]
+ =dev-python/sniffio-1*[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+ dev-python/trustme[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ # anyio and trio are not in the tree
+ sed -i 's/^@pytest.mark.\(anyio\|trio\)/@pytest.mark.skip/' \
+ tests/async_tests/test_*.py || die
+ sed -i '/^import trio/d' tests/utils.py || die
+ # pproxy is not in the tree, the associated fixture
+ # must be disabled to prevent errors during test setup
+ sed -i 's/def proxy_server().*/&\n pytest.skip()/' \
+ tests/conftest.py || die
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ local skipped_tests=(
+ # Require Internet access or hypercorn (not in the tree)
+ tests/test_threadsafety.py::test_threadsafe_basic
+ tests/sync_tests/test_interfaces.py::test_http_request
+ tests/sync_tests/test_interfaces.py::test_https_request
+ tests/sync_tests/test_interfaces.py::test_http2_request
+ tests/sync_tests/test_interfaces.py::test_closing_http_request
+
tests/sync_tests/test_interfaces.py::test_connection_pool_get_connection_info
+
tests/sync_tests/test_interfaces.py::test_max_keepalive_connections_handled_correctly
+ tests/sync_tests/test_interfaces.py::test_explicit_backend_name
+ tests/sync_tests/test_interfaces.py::test_connection_timeout_tcp
+
tests/sync_tests/test_interfaces.py::test_broken_socket_detection_many_open_files
+ tests/sync_tests/test_retries.py::test_no_retries
+ tests/sync_tests/test_retries.py::test_retries_exceeded
+ tests/sync_tests/test_retries.py::test_retries_enabled
+ # Require hypercorn
+ tests/sync_tests/test_interfaces.py::test_connection_timeout_uds
+ )
+ pytest -vv ${skipped_tests[@]/#/--deselect } \
+ || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/httpcore/metadata.xml b/dev-python/httpcore/metadata.xml
new file mode 100644
index 00000000000..3b3eef0fd95
--- /dev/null
+++ b/dev-python/httpcore/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd";>
+<pkgmetadata>
+ <maintainer type="project">
+ <email>[email protected]</email>
+ <name>Python</name>
+ </maintainer>
+ <upstream>
+ <remote-id type="pypi">httpcore</remote-id>
+ <remote-id type="github">encode/httpcore</remote-id>
+ <bugs-to>https://github.com/encode/httpcore/issues</bugs-to>
+ </upstream>
+</pkgmetadata>
