[gentoo-commits] proj/kde:master commit in: kde-plasma/plasma-firewall/

[Andreas Sturmlechner]

commit:     a40bf65300ee87fae26329588a4ddd82c36a7d1a
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 22 23:31:53 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jan 22 23:58:45 2021 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=a40bf653

kde-plasma/plasma-firewall: 5.20.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../plasma-firewall/plasma-firewall-5.20.90.ebuild | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.20.90.ebuild 
b/kde-plasma/plasma-firewall/plasma-firewall-5.20.90.ebuild
new file mode 100644
index 0000000000..83c3d04d67
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.20.90.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+KFMIN=5.78.0
+QTMIN=5.15.2
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall";
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+       >=dev-qt/qtdbus-${QTMIN}:5
+       >=dev-qt/qtdeclarative-${QTMIN}:5
+       >=dev-qt/qtgui-${QTMIN}:5
+       >=dev-qt/qtnetwork-${QTMIN}:5
+       >=dev-qt/qtx11extras-${QTMIN}:5
+       >=dev-qt/qtxml-${QTMIN}:5
+       >=kde-frameworks/kauth-${KFMIN}:5
+       >=kde-frameworks/kcmutils-${KFMIN}:5
+       >=kde-frameworks/kconfig-${KFMIN}:5
+       >=kde-frameworks/kcoreaddons-${KFMIN}:5
+       >=kde-frameworks/kdeclarative-${KFMIN}:5
+       >=kde-frameworks/ki18n-${KFMIN}:5
+       >=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+       ${PYTHON_DEPS}
+       || (
+               net-firewall/firewalld
+               net-firewall/ufw
+       )
+"
+
+src_prepare() {
+       ecm_src_prepare
+       # this kind of cmake magic doesn't work for us at all.
+       sed -e "1 s:^.*$:\#\!/usr/bin/env python3.8:" \
+               -i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}