[gentoo-commits] repo/gentoo:master commit in: app-arch/wimlib/

[Sam James]

commit:     fd58b053554f24cdab16f56e30560e3275e6a005
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Jan 19 03:14:04 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Jan 19 03:14:04 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fd58b053

app-arch/wimlib: bump to 1.13.3

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-arch/wimlib/Manifest             |  1 +
 app-arch/wimlib/wimlib-1.13.3.ebuild | 73 ++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/app-arch/wimlib/Manifest b/app-arch/wimlib/Manifest
index a14a38085f3..05d9a3f639d 100644
--- a/app-arch/wimlib/Manifest
+++ b/app-arch/wimlib/Manifest
@@ -1 +1,2 @@
 DIST wimlib-1.13.0.tar.gz 1035146 BLAKE2B 
305d4bd4a0299c99b537c2bc59c674740239d3fe7c240038f4846849f36046ef587b04643d5a482c876668bf8f9a94a7b45a5e4f12c6d235a579a08c3879acff
 SHA512 
a7ec729dda07b3884a851533a3c9e9db3061d9f6273ec318e40ece3687f4671f66989c07c080fa9cdcf5f01318c5eba7256b58f15f711b3ff14f4eb61c2114cb
+DIST wimlib-1.13.3.tar.gz 1030667 BLAKE2B 
2b897392bed3c4a390479f34925474c229ee835ab624c81a0baa7ebb8f3484f27aa4efb2a440debdcafe23b152b385bbe0f198d6f0560e8f88a34c7328a74edd
 SHA512 
5c6e3bd1d7bda55812c818cc527cd241ac8a15276648f2a307db1f2a858de0b322e9f2beffda5bab991811aee3f4a953c3e31847bfa76a7d32ad5850595a15d4

diff --git a/app-arch/wimlib/wimlib-1.13.3.ebuild 
b/app-arch/wimlib/wimlib-1.13.3.ebuild
new file mode 100644
index 00000000000..a6115205d0c
--- /dev/null
+++ b/app-arch/wimlib/wimlib-1.13.3.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools pax-utils
+if [[ -z ${PV%%*9999} ]]; then
+       inherit git-r3
+       EGIT_REPO_URI="git://wimlib.net/${PN}"
+else
+       MY_PV="${PV/_/-}"
+       MY_PV="${MY_PV^^}"
+       SRC_URI="https://wimlib.net/downloads/${PN}-${MY_PV}.tar.gz";
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="The open source Windows Imaging (WIM) library"
+HOMEPAGE="https://wimlib.net/";
+
+LICENSE="|| ( GPL-3+ LGPL-3+ ) CC0-1.0"
+SLOT="0"
+IUSE="cpu_flags_x86_ssse3 fuse iso ntfs openssl test threads yasm"
+REQUIRED_USE="cpu_flags_x86_ssse3? ( !openssl )"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+       virtual/pkgconfig
+       cpu_flags_x86_ssse3? (
+               yasm? ( dev-lang/yasm )
+               !yasm? ( dev-lang/nasm )
+       )
+"
+RDEPEND="
+       dev-libs/libxml2:2
+       ntfs? ( sys-fs/ntfs3g )
+       fuse? ( sys-fs/fuse:0 )
+       openssl? ( dev-libs/openssl:0= )
+       iso? (
+               app-arch/cabextract
+               app-cdr/cdrtools
+       )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       local myeconfargs=(
+               $(use_with ntfs ntfs-3g)
+               $(use_with fuse)
+               $(use_enable cpu_flags_x86_ssse3 ssse3-sha1)
+               $(use_with openssl libcrypto)
+               $(use_enable threads multithreaded-compression)
+               $(use_enable test test-support)
+               --disable-static
+       )
+       ac_cv_prog_NASM="$(usex yasm yasm nasm)" \
+               econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+       default
+       pax-mark m "${S}"/.libs/wimlib-imagex
+}
+
+src_install() {
+       default
+       find "${ED}" -name '*.la' -delete || die
+}