[gentoo-commits] repo/gentoo:master commit in: dev-lua/lua-term/

[Conrad Kostecki]

commit:     099724ceaf973f76d87340056b53330dfe050178
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 29 15:15:44 2020 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sun Nov 29 15:15:44 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=099724ce

dev-lua/lua-term: update lua eclass ebuild

Updated ebuild not to use multiple times clean.

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 dev-lua/lua-term/lua-term-0.7-r101.ebuild | 66 +++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

diff --git a/dev-lua/lua-term/lua-term-0.7-r101.ebuild 
b/dev-lua/lua-term/lua-term-0.7-r101.ebuild
new file mode 100644
index 00000000000..d9f090f2e7e
--- /dev/null
+++ b/dev-lua/lua-term/lua-term-0.7-r101.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+MY_PV="0.07"
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Terminal operations for Lua"
+HOMEPAGE="https://github.com/hoelzro/lua-term";
+SRC_URI="https://github.com/hoelzro/lua-term/archive/${MY_PV}.tar.gz -> 
${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+       default
+
+       # Respect users CFLAGS
+       sed -e 's/-O3//g' -i Makefile
+
+       lua_copy_sources
+}
+
+lua_src_compile() {
+       pushd "${BUILD_DIR}" || die
+
+       local myemakeargs=(
+               "CC=$(tc-getCC)"
+               "CFLAGS=${CFLAGS} ${LDFLAGS} $(lua_get_CFLAGS)"
+       )
+
+       emake "${myemakeargs[@]}" all
+
+       popd
+}
+
+src_compile() {
+       lua_foreach_impl lua_src_compile
+}
+
+lua_src_install() {
+       pushd "${BUILD_DIR}" || die
+
+       local myemakeargs=(
+               LUA_LIBDIR="${ED}/$(lua_get_cmod_dir)/term"
+               LUA_SHARE="${ED}/$(lua_get_lmod_dir)/term"
+       )
+
+       emake "${myemakeargs[@]}" install
+
+       popd
+}
+
+src_install() {
+       lua_foreach_impl lua_src_install
+}