[gentoo-commits] repo/gentoo:master commit in: dev-games/tiled/

[Michael Palimaka]

commit:     a7489217530ea5684eace170dccb9502a923e746
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 24 12:08:02 2020 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Tue Nov 24 12:08:41 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a7489217

dev-games/tiled: version bump 1.4.3

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Michael Palimaka <kensington <AT> gentoo.org>

 dev-games/tiled/Manifest           |  1 +
 dev-games/tiled/tiled-1.4.3.ebuild | 71 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index 39f1d38197d..2fcba421e0b 100644
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-1.4.2.tar.gz 17806729 BLAKE2B 
9f9e6b97c6d95b1f8a1ad6da3540aaf9310a705b412005752afe72c3ce8e35025559ed0e7aaf36a1d65284c29d8406bdc58121f6c13bb658ff84ff43fde7f403
 SHA512 
1fddd8c8d67e4eaf116c82e276b0941e6dae7c529f2132e49da77d7e215fc7106d5fd3ef55d118f799153b57340effcf2481a131a436be7f00f61c4fc4bd45d2
+DIST tiled-1.4.3.tar.gz 17806808 BLAKE2B 
81b5a32cc1e6f5f3b4af5520752d34572f0e78aad90df435d075b53ac18b39961aa22d23cff614cd83f0883fd2fd2bca69026160cb8b1b727fddaeff5764babe
 SHA512 
1e75e323733e05563bf542364778d95f2f22484ec0d85b4a9e7fac782c117934b37b049724979be5c83de86a3900c7ca2e9f3c5a660c530d2ecd0f023eb22c2e

diff --git a/dev-games/tiled/tiled-1.4.3.ebuild 
b/dev-games/tiled/tiled-1.4.3.ebuild
new file mode 100644
index 00000000000..fc9a62d7bd9
--- /dev/null
+++ b/dev-games/tiled/tiled-1.4.3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+inherit python-single-r1 qmake-utils xdg-utils
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="https://www.mapeditor.org/";
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz";
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+       app-arch/zstd:=
+       >=dev-qt/qtcore-5.14:5
+       >=dev-qt/qtdeclarative-5.14:5
+       >=dev-qt/qtgui-5.14:5
+       >=dev-qt/qtnetwork-5.14:5
+       >=dev-qt/qtwidgets-5.14:5
+       sys-libs/zlib
+       python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+       dev-qt/linguist-tools:5
+       virtual/pkgconfig
+"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+       eqmake5 \
+               LIBDIR="/usr/$(get_libdir)" \
+               PREFIX="/usr" \
+               SYSTEM_ZSTD="yes" \
+               DISABLE_PYTHON_PLUGIN="$(usex !python)"
+}
+
+src_install() {
+       emake INSTALL_ROOT="${D}" install
+
+       einstalldocs
+
+       if use examples ; then
+               docompress -x /usr/share/doc/${PF}/examples
+               dodoc -r examples
+       fi
+}
+
+pkg_postinst() {
+       xdg_icon_cache_update
+       xdg_desktop_database_update
+       xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+       xdg_icon_cache_update
+       xdg_desktop_database_update
+       xdg_mimeinfo_database_update
+}