commit: 2536a645670a80be1cf4379a8c888336cbf73db9
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 31 07:55:08 2020 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Oct 31 08:33:38 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2536a645
dev-python/ipython: Bump to 7.19.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/ipython/Manifest | 1 +
dev-python/ipython/ipython-7.19.0.ebuild | 136 +++++++++++++++++++++++++++++++
2 files changed, 137 insertions(+)
diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 578565de48b..3bb1ec13441 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,2 +1,3 @@
DIST ipython-7.16.1.tar.gz 5136303 BLAKE2B
9baf42c9befa50d78eec29d012aeae7f01886f29642a01845afd4a96d0efb7a4df5b14b68aeeb22d1d621e5427b219f717688a1d5074a6e70ad0509c7ca73a46
SHA512
60259fd6270b0355be67b4f620a58b56ae86e69e14debe2df86df6118548f2290ab3927b8dfab20db1ebd675df697d05eb6994b93625a7b8b6ea07112ddf63bd
DIST ipython-7.18.1.tar.gz 5139337 BLAKE2B
936759db4377767537766a2baf0bff2adf1a95d17438899e1e1611d725e796d8ab78fcb8f1ca14d8d41171af64fa67abe9fadf84c6ca3cf17bb1d83fa2ba4268
SHA512
71f495021df56bbea97fb26b9274e54f7662875b7690a9493bdf682635e048d9ec53a947ee9b0d487634a3a8c639f0d93c6639b3a0dd20bdfefbb4c53fb53799
+DIST ipython-7.19.0.tar.gz 5225775 BLAKE2B
1909d8336e7fc90959da4ca33ad7edcb8c2dec0a5aa20ca6f643ef53482fe7bf0d52e2bbec7cf97e72a1fd4d37af45ba01166febb25f35b52d69ffc062f0f0e8
SHA512
5350a125da3050acaea4899939a3b9d779009a2f5769fc9f3aa514ce029df050069ef9310d3255ad62f28912b4dec39207267248d3a2c3e9131cffd691322622
diff --git a/dev-python/ipython/ipython-7.19.0.ebuild
b/dev-python/ipython/ipython-7.19.0.ebuild
new file mode 100644
index 00000000000..dfdb4d403f3
--- /dev/null
+++ b/dev-python/ipython/ipython-7.19.0.ebuild
@@ -0,0 +1,136 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+ dev-python/backcall[${PYTHON_USEDEP}]
+ dev-python/decorator[${PYTHON_USEDEP}]
+ >=dev-python/jedi-0.10[${PYTHON_USEDEP}]
+ >=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+ dev-python/pickleshare[${PYTHON_USEDEP}]
+ >=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+ <dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+ dev-python/pygments[${PYTHON_USEDEP}]
+ dev-python/traitlets[${PYTHON_USEDEP}]
+ matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="${CDEPEND}
+ nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
+
+BDEPEND="
+ test? (
+ ${CDEPEND}
+ app-text/dvipng[truetype]
+ >=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+ dev-python/nbformat[${PYTHON_USEDEP}]
+ dev-python/nose[${PYTHON_USEDEP}]
+ >=dev-python/numpy-1.14[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/testpath[${PYTHON_USEDEP}]
+ )
+ doc? (
+ >=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ >=dev-python/sphinx-2[${PYTHON_USEDEP}]
+ )"
+
+PDEPEND="
+ notebook? (
+ dev-python/notebook[${PYTHON_USEDEP}]
+ dev-python/ipywidgets[${PYTHON_USEDEP}]
+ dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+ )
+ qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+ smp? (
+ >=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+ >=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+ )"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+ # Remove out of date insource files
+ rm IPython/extensions/cythonmagic.py || die
+ rm IPython/extensions/rmagic.py || die
+
+ # Prevent un-needed download during build
+ if use doc; then
+ sed -e "/^ 'sphinx.ext.intersphinx',/d" -i
docs/source/conf.py || die
+ fi
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ emake -C docs html_noapi
+ HTML_DOCS=( docs/build/html/. )
+ fi
+}
+
+src_test() {
+ virtx distutils-r1_src_test
+}
+
+python_test() {
+ distutils_install_for_testing
+ pushd "${TEST_DIR}" >/dev/null || die
+ "${TEST_DIR}"/scripts/iptest || die
+ popd >/dev/null || die
+}
+
+python_install() {
+ distutils-r1_python_install
+
+ # Create ipythonX.Y symlinks.
+ # TODO:
+ # 1. do we want them for pypy? No. pypy has no numpy
+ # 2. handle it in the eclass instead (use _python_ln_rel).
+ # With pypy not an option the dosym becomes unconditional
+ dosym ../lib/python-exec/${EPYTHON}/ipython \
+ /usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+ distutils-r1_python_install_all
+
+ if use examples; then
+ dodoc -r examples
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+}
+
+pkg_postinst() {
+ optfeature "sympyprinting" dev-python/sympy
+ optfeature "cythonmagic" dev-python/cython
+ optfeature "%lprun magic command" dev-python/line_profiler
+ optfeature "%mprun magic command" dev-python/memory_profiler
+
+ if use nbconvert; then
+ if ! has_version app-text/pandoc ; then
+ einfo "Node.js will be used to convert notebooks to
other formats"
+ einfo "like HTML. Support for that is still
experimental. If you"
+ einfo "encounter any problems, please use
app-text/pandoc instead."
+ fi
+ fi
+}
