commit: be6786733130233cc99087a90e45f0b264931a6a
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 27 13:18:28 2020 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Oct 27 13:18:28 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=be678673
net-wireless/blueman: Bump to 2.1.4
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
net-wireless/blueman/Manifest | 1 +
net-wireless/blueman/blueman-2.1.4.ebuild | 132 ++++++++++++++++++++++++++++++
2 files changed, 133 insertions(+)
diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index f338f72712d..2235f5f8c7c 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1 +1,2 @@
DIST blueman-2.1.3.tar.xz 950772 BLAKE2B
bec7c8da59b94e8f30ff5f41e057ae5662928a4469b46d0ad2b33521a9b3a5de94056f6f35440d90e05116b1dd83dcd2437f1c00fb6b9532c14ab0698716c57a
SHA512
376007c6e857f0e10a4d5e4bc2a50f6d170d393389d3aa5d02728646bf27e2fe5c08fb835bb5432a980d2b6c70c348a0274015552be6229c15a89c34c0d105f2
+DIST blueman-2.1.4.tar.xz 983816 BLAKE2B
de8d475b0aec5b037df43fdb76ebbf4fdb05367f166c14cda818badf49376f2a91de246f991167a57ecaa82a84ac84b4e91f600237c35d86e27431a760192996
SHA512
b8b54942092c1984cfac0cf73e2ac23f7693cb3ee0aa4cfaab1fa0282de4afd539f6860d5541523b542956b2efa31da3ec012dcc39d92fd699d0b8479df641ff
diff --git a/net-wireless/blueman/blueman-2.1.4.ebuild
b/net-wireless/blueman/blueman-2.1.4.ebuild
new file mode 100644
index 00000000000..90544f6ccff
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.1.4.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{6..8} )
+inherit autotools gnome2-utils linux-info python-single-r1 systemd xdg-utils
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman";
+
+if [[ ${PV} == "9999" ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/blueman-project/blueman.git";
+ KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+else
+
SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV/_/.}/${P/_/.}.tar.xz";
+ S=${WORKDIR}/${P/_/.}
+ KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+# icons are GPL-2
+# source files are mixed GPL-3+ and GPL-2+
+LICENSE="GPL-3+ GPL-2"
+SLOT="0"
+IUSE="appindicator network nls policykit pulseaudio"
+
+DEPEND="
+ $(python_gen_cond_dep '
+ dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+ ')
+ >=net-wireless/bluez-5:=
+ ${PYTHON_DEPS}"
+BDEPEND="
+ $(python_gen_cond_dep '
+ dev-python/cython[${PYTHON_MULTI_USEDEP}]
+ ')
+ virtual/pkgconfig
+ nls? ( dev-util/intltool sys-devel/gettext )"
+RDEPEND="${DEPEND}
+ $(python_gen_cond_dep '
+ dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+ ')
+ sys-apps/dbus
+ x11-libs/gtk+:3[introspection]
+ x11-libs/libnotify[introspection]
+ || (
+ x11-themes/adwaita-icon-theme
+ x11-themes/faenza-icon-theme
+ x11-themes/mate-icon-theme
+ )
+ appindicator? ( dev-libs/libappindicator:3[introspection] )
+ network? (
+ net-firewall/iptables
+ || (
+ sys-apps/net-tools
+ sys-apps/iproute2
+ )
+ || (
+ net-dns/dnsmasq
+ net-misc/dhcp
+ >=net-misc/networkmanager-0.8
+ )
+ )
+ policykit? ( sys-auth/polkit )
+ pulseaudio? (
+ || (
+ media-sound/pulseaudio[bluetooth]
+ media-sound/pulseaudio-modules-bt
+ )
+ )
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_pretend() {
+ if use network; then
+ local CONFIG_CHECK="~BRIDGE ~IP_NF_IPTABLES
+ ~IP_NF_NAT ~IP_NF_TARGET_MASQUERADE"
+ check_extra_config
+ fi
+}
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ # replace py-compile to fix py3
+ [[ ${PV} == 9999 ]] && eautoreconf || eautomake
+}
+
+src_configure() {
+ local myconf=(
+ --disable-runtime-deps-check
+ --disable-static
+ --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+ --with-systemduserunitdir="$(systemd_get_userunitdir)"
+ --with-dhcp-config="/etc/dhcp/dhcpd.conf"
+ $(use_enable appindicator)
+ $(use_enable policykit polkit)
+ $(use_enable nls)
+ $(use_enable pulseaudio)
+ # thunar integration is a single data file with no extra deps
+ # so install it unconditionally
+ --enable-thunar-sendto
+ )
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ default
+
+ if use policykit; then
+ # Allow users in plugdev group to modify connections
+ insinto /usr/share/polkit-1/rules.d
+ doins "${FILESDIR}/01-org.blueman.rules"
+ fi
+
+ rm "${D}"/$(python_get_sitedir)/*.la || die
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}
