commit: 12a427d9d80be9bad41eb2f394b4bb1552e3dd43
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 10 05:34:23 2020 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Oct 10 05:53:52 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=12a427d9
dev-python/tox: Bump to 3.20.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/tox/Manifest | 1 +
dev-python/tox/tox-3.20.1.ebuild | 70 ++++++++++++++++++++++++++++++++++++++++
2 files changed, 71 insertions(+)
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 1d6ea029430..ec1c5c34751 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,2 +1,3 @@
DIST tox-3.19.0.tar.gz 296499 BLAKE2B
cad41c7791108ecdf6efc7bca99623c66d1d8ffbb2b06688eb84e575f14958ba2b497e0035ccc331fc8e0ce667824cba2c8dd37488ac48b3c16902c7b546074b
SHA512
7a542282dc2fdef7ab8aff04372aeeeaad54b83bd7f1022c1c60465604d67a5984abcea7d409b8593b646192407c78cb88422aa4dfd11fb2a2d9da520aeafb39
DIST tox-3.20.0.tar.gz 297432 BLAKE2B
279a6d407c4a490309843ba30e62fe2f0c6ace63af2dfd5b5c2fc8ee6ab784b99da56e9d7d76cd0170f85432bef500c31b824fee32558f7f21d4491385d13b4a
SHA512
eb8e55eb3c232356cdb3e1477399ef055df497f1276f0b5c5423f30c780e2619067d1e44c2d6702016e63f96a76d04d0c5e7b6c6f1faa1a98f1dcc5b1cbeae39
+DIST tox-3.20.1.tar.gz 297516 BLAKE2B
2a13059bce229f30670e247b17ffd03d4b0d907b2fa7eb7d2f6848ada8d81e1a0aad983748c4346dfa61877f88edd22e4616ed20efcbd15da34fdc1c87b4439a
SHA512
0989cc3dfd25eb3d1236d973d490f12c81273c93e84140b54342217eb73dd944f446c7ce9fe228b644d764b94300f1c6ccaf94e442d0e34835d05de84cccabd6
diff --git a/dev-python/tox/tox-3.20.1.ebuild b/dev-python/tox/tox-3.20.1.ebuild
new file mode 100644
index 00000000000..499658c518d
--- /dev/null
+++ b/dev-python/tox/tox-3.20.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="https://tox.readthedocs.io https://github.com/tox-dev/tox
https://pypi.org/project/tox/";
+SRC_URI="https://github.com/tox-dev/tox/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+# doc disabled because of missing deps in tree
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-python/filelock[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep '
+ >=dev-python/importlib_metadata-1.1[${PYTHON_USEDEP}]
+ ' python3_{5,6,7} pypy3)
+ dev-python/packaging[${PYTHON_USEDEP}]
+ >=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+ dev-python/pip[${PYTHON_USEDEP}]
+ dev-python/py[${PYTHON_USEDEP}]
+ >=dev-python/six-1.14[${PYTHON_USEDEP}]
+ dev-python/toml[${PYTHON_USEDEP}]
+ >=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]"
+# TODO: figure out how to make tests work without the package being
+# installed first.
+BDEPEND="
+ dev-python/setuptools_scm[${PYTHON_USEDEP}]
+ test? (
+ ${RDEPEND}
+ >=dev-python/flaky-3.4.0[${PYTHON_USEDEP}]
+ >=dev-python/freezegun-0.3.11[${PYTHON_USEDEP}]
+ dev-python/pathlib2[${PYTHON_USEDEP}]
+ >=dev-python/pytest-4.0.0[${PYTHON_USEDEP}]
+ dev-python/pytest-mock[${PYTHON_USEDEP}]
+ =dev-python/tox-${PV}-${PR}[${PYTHON_USEDEP}]
+ )"
+
+src_prepare() {
+ distutils-r1_src_prepare
+
+ # broken without internet
+ sed -i -e 's:test_provision_non_canonical_dep:_&:' \
+ tests/unit/session/test_provision.py || die
+ sed -i -e 's:test_provision_interrupt_child:_&:' \
+ tests/integration/test_provision_int.py || die
+ # broken with our mock version (?)
+ sed -i -e 's:test_create_KeyboardInterrupt:_&:' \
+ tests/unit/test_venv.py || die
+ # broken with Gentoo Python layout
+ sed -i -e 's:test_tox_get_python_executable:_&:' \
+ -e 's:test_find_alias_on_path:_&:' \
+ tests/unit/interpreters/test_interpreters.py || die
+
+ export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+ distutils_install_for_testing
+ pytest -vv --no-network || die "Testsuite failed under ${EPYTHON}"
+}
