[gentoo-commits] repo/gentoo:master commit in: net-misc/vncsnapshot/

[Sam James]

commit:     bc7f74e1dff8f3dd67bb1167e768909636dfb86d
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 14 22:26:58 2020 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Sep 14 22:26:58 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bc7f74e1

net-misc/vncsnapshot: EAPI 7, respect tc variables

* EAPI 4->7
* Respect AR, RANLIB
* Don't clobber make (call $(MAKE) so jobserver persists)

Closes: https://bugs.gentoo.org/742149
Closes: https://bugs.gentoo.org/725208
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-misc/vncsnapshot/vncsnapshot-1.2a.ebuild | 34 +++++++++++++++++++++-------
 1 file changed, 26 insertions(+), 8 deletions(-)

diff --git a/net-misc/vncsnapshot/vncsnapshot-1.2a.ebuild 
b/net-misc/vncsnapshot/vncsnapshot-1.2a.ebuild
index 221b1344f24..41283434b79 100644
--- a/net-misc/vncsnapshot/vncsnapshot-1.2a.ebuild
+++ b/net-misc/vncsnapshot/vncsnapshot-1.2a.ebuild
@@ -1,9 +1,9 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
+EAPI=7
 
-inherit eutils toolchain-funcs
+inherit toolchain-funcs
 
 DESCRIPTION="A command-line tool for taking JPEG snapshots of VNC servers"
 HOMEPAGE="http://vncsnapshot.sourceforge.net/";
@@ -12,32 +12,50 @@ SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.bz2"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ppc x86"
-IUSE=""
 
 DEPEND="
        virtual/jpeg
        >=sys-libs/zlib-1.1.4"
 RDEPEND="${DEPEND}"
 
+PATCHES=(
+       "${FILESDIR}/${P}-amd64grey.patch"
+)
+
 src_prepare() {
-       epatch "${FILESDIR}/${P}-amd64grey.patch"
+       default
+
        sed \
                -e 's:-I/usr/local/include::g' \
                -e 's:-L/usr/local/lib::g' \
                -e '/^all:/s|$(SUBDIRS:.dir=.all)||g' \
                -e '/^vnc/s|$| $(SUBDIRS:.dir=.all)|g' \
                -i Makefile || die
+
+       # Preserve make instance
+       sed -i -e 's/make/$(MAKE)/' Makefile || die
+
+       # Respect RANLIB
+       sed -i -e 's/ranlib/$(RANLIB)/' rdr/Makefile || die
 }
 
 src_compile() {
-       #note: We override CDEBUGFLAGS instead of CFLAGS because otherwise
-       #      we lost the INCLUDES in the makefile.
+       # Note: We override CDEBUGFLAGS instead of CFLAGS because otherwise
+       #       we lose the INCLUDES in the makefile.
        # bug #295741
-       emake CDEBUGFLAGS="${CXXFLAGS}" CC="$(tc-getCC)" CXX="$(tc-getCXX)"
+       local args=(
+               AR="$(tc-getAR)"
+               CDEBUGFLAGS="${CXXFLAGS}"
+               CC="$(tc-getCC)"
+               CXX="$(tc-getCXX)"
+               RANLIB="$(tc-getRANLIB)"
+       )
+       emake "${args[@]}"
 }
 
 src_install() {
        dobin vncsnapshot
-       cp vncsnapshot.man1 vncsnapshot.1
+
+       cp vncsnapshot.man1 vncsnapshot.1 || die
        doman vncsnapshot.1
 }