commit: 068d532e7a1047742b48f72f0889529200341ff2
Author: Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 15 12:28:11 2020 +0000
Commit: Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Sat Aug 15 12:28:27 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=068d532e
net-misc/remmina: bump to 1.4.8
Package-Manager: Portage-3.0.2, Repoman-2.3.23
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>
net-misc/remmina/Manifest | 1 +
net-misc/remmina/remmina-1.4.8.ebuild | 98 +++++++++++++++++++++++++++++++++++
2 files changed, 99 insertions(+)
diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index c084b43dacc..6f6f809f6c6 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,2 +1,3 @@
DIST Remmina-v1.4.5.tar.gz 1787506 BLAKE2B
095a01cca168daaef9ef59ff5adb9bb475467e8e8c42cac74a1a605627b09aa7246aa941b514b0de29739516aa988148f377040ed8629df3d5b17f0b1158cf76
SHA512
fec07b488db8d438aa6a0263e13557c10f1401a81b3371a2da03a1037d51f8e58e88652a15c6d6ce9e02535ef93ed0f9c5b674ab5efab430380f4b7dd57c4d9d
DIST Remmina-v1.4.7.tar.gz 1908687 BLAKE2B
a6656821d727914f70bafe50d5c3764e3c36a4753c618048b91eadc1fa27b8f03bcd313b99cfd46cadc446b85b583994528895f9fb755d6c8ee28e0b0bab66d1
SHA512
ebe1e62e090062107ed6674d494255bac9e3d175553bc5ae949aa1bfc9e1de4b59f35f523ee36b08bb02580513d3b585344b9864001dd991cac656f1c13116e9
+DIST Remmina-v1.4.8.tar.gz 1998851 BLAKE2B
80427d06c041d6315fa8fabe90aa8a52ebd2cd1a76ab0e74672f54328d5fa9d0d287e551a5027e5ef60471ce4d934cfe745742058f26e7b93a95e2a1f85dbfd9
SHA512
cf8ea93904a1643f480d7de72bc4154570bcf184150ffc4b3b06699c95f354bc2f4f595c3b00c6c87e9797dc60bcb9993913647b2073f1e85977026f290d81bf
diff --git a/net-misc/remmina/remmina-1.4.8.ebuild
b/net-misc/remmina/remmina-1.4.8.ebuild
new file mode 100644
index 00000000000..f73e076ebcd
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.8.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake eutils xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/";
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz";
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="appindicator crypt cups examples gnome-keyring kwallet libressl nls
spice ssh rdp telemetry telepathy vnc webkit zeroconf"
+
+DEPEND="
+ dev-libs/glib:2
+ dev-libs/json-glib
+ dev-libs/libsodium:=
+ net-libs/libsoup
+ x11-libs/gdk-pixbuf
+ x11-libs/gtk+:3
+ x11-libs/libX11
+ x11-libs/libxkbfile
+ appindicator? ( dev-libs/libappindicator:3 )
+ crypt? ( dev-libs/libgcrypt:0= )
+ rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129
+ <net-misc/freerdp-3
+ cups? ( net-print/cups:= ) )
+ gnome-keyring? ( app-crypt/libsecret )
+ kwallet? ( kde-frameworks/kwallet )
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ spice? ( net-misc/spice-gtk[gtk3] )
+ ssh? ( net-libs/libssh:0=[sftp]
+ x11-libs/vte:2.91 )
+ telepathy? ( net-libs/telepathy-glib )
+ vnc? ( net-libs/libvncserver[jpeg] )
+ webkit? ( net-libs/webkit-gtk:4 )
+ zeroconf? ( || ( >=net-dns/avahi-0.8-r2[dbus,gtk]
<net-dns/avahi-0.8-r2[dbus,gtk3] ) )
+"
+BDEPEND="
+ dev-util/intltool
+ virtual/pkgconfig
+ nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+ ${DEPEND}
+ virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+ xdg_environment_reset
+ cmake_src_prepare
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DWITH_APPINDICATOR=$(usex appindicator)
+ -DWITH_GCRYPT=$(usex crypt)
+ -DWITH_EXAMPLES=$(usex examples)
+ -DWITH_LIBSECRET=$(usex gnome-keyring)
+ -DWITH_KF5WALLET=$(usex kwallet)
+ -DWITH_GETTEXT=$(usex nls)
+ -DWITH_TRANSLATIONS=$(usex nls)
+ -DWITH_FREERDP=$(usex rdp)
+ -DWITH_CUPS=$(usex cups)
+ -DWITH_SPICE=$(usex spice)
+ -DWITH_LIBSSH=$(usex ssh)
+ -DWITH_VTE=$(usex ssh)
+ -DWITH_TELEPATHY=$(usex telepathy)
+ -DWITH_LIBVNCSERVER=$(usex vnc)
+ -DWITH_WWW=$(usex webkit)
+ -DWITH_AVAHI=$(usex zeroconf)
+ -DWITH_NEWS=$(usex telemetry)
+ -DWITH_ICON_CACHE=OFF
+ -DWITH_UPDATE_DESKTOP_DB=OFF
+ )
+ cmake_src_configure
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+
+ elog "To get additional features, some optional runtime dependencies"
+ elog "may be installed:"
+ elog ""
+ optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+ optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}
