[gentoo-commits] repo/gentoo:master commit in: net-libs/libpsl/

[Lars Wendler]

commit:     f08aae011ddd3e7611975a50d1e6a269fc295354
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 19 07:29:48 2020 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Sun Jul 19 07:29:56 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f08aae01

net-libs/libpsl: Bump to version 0.21.1

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 net-libs/libpsl/Manifest             |  1 +
 net-libs/libpsl/libpsl-0.21.1.ebuild | 70 ++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/net-libs/libpsl/Manifest b/net-libs/libpsl/Manifest
index f1e5d5420b3..1542bbed954 100644
--- a/net-libs/libpsl/Manifest
+++ b/net-libs/libpsl/Manifest
@@ -1 +1,2 @@
 DIST libpsl-0.21.0.tar.gz 9217951 BLAKE2B 
fd93b71ae4969bb920af26e10e0e419dab62db37197046b0f4e4a0e009a150582df6d4c8fe33218fa8be869e6ad9688d3c325c3f635da5560e29269daa461668
 SHA512 
165c4f0b0640a813d512bd916e1532e32e43c8c81a5efd048f3a5b07b1b3c9129b4c4b5008b8b11a7c1b3914caea17564321389cd350bf1d687d53a97f2afa4d
+DIST libpsl-0.21.1.tar.gz 9199351 BLAKE2B 
87c72651303a7870fd3f742e9ce8028e0dd48d3ded78ae7dea317ce54b98975f372429399b6a2d6746fd8e074d6a3ed13772b6c173f96c3a86aa7d726fd75586
 SHA512 
a5084b9df4ff2a0b1f5074b20972efe0da846473396d27b57967c7f6aa190ab3c910b4bfc4f8f03802f08decbbad5820d850c36ad59610262ae37fe77de0c7f5

diff --git a/net-libs/libpsl/libpsl-0.21.1.ebuild 
b/net-libs/libpsl/libpsl-0.21.1.ebuild
new file mode 100644
index 00000000000..9c732ca972f
--- /dev/null
+++ b/net-libs/libpsl/libpsl-0.21.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=(python3_{6,7,8})
+inherit multilib-minimal python-any-r1
+
+DESCRIPTION="C library for the Public Suffix List"
+HOMEPAGE="https://github.com/rockdaboot/libpsl";
+SRC_URI="https://github.com/rockdaboot/${PN}/releases/download/${PV}/${P}.tar.gz";
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 
~sparc ~x86"
+IUSE="icu +idn +man"
+
+RDEPEND="
+       icu? ( !idn? ( dev-libs/icu:=[${MULTILIB_USEDEP}] ) )
+       idn? (
+               dev-libs/libunistring[${MULTILIB_USEDEP}]
+               net-dns/libidn2:=[${MULTILIB_USEDEP}]
+       )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}
+       dev-util/gtk-doc-am
+       sys-devel/gettext
+       virtual/pkgconfig
+       man? ( dev-libs/libxslt )
+"
+
+pkg_pretend() {
+       if use icu && use idn ; then
+               ewarn "\"icu\" and \"idn\" USE flags are enabled."
+               ewarn "Using \"idn\"."
+       fi
+}
+
+multilib_src_configure() {
+       local myeconfargs=(
+               --disable-asan
+               --disable-cfi
+               --disable-ubsan
+               $(use_enable man)
+       )
+
+       # Prefer idn even if icu is in USE as well
+       if use idn ; then
+               myeconfargs+=(
+                       --enable-builtin=libidn2
+                       --enable-runtime=libidn2
+               )
+       elif use icu ; then
+               myeconfargs+=(
+                       --enable-builtin=libicu
+                       --enable-runtime=libicu
+               )
+       else
+               myeconfargs+=( --disable-runtime )
+       fi
+
+       ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+       default
+
+       find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}