commit: 30457c628a8aaff54b01ff87d22eb66ecf0fccb0
Author: Jeffrey Lin <jeffrey <AT> icurse <DOT> nl>
AuthorDate: Sat Jun 20 19:34:03 2020 +0000
Commit: Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Thu Jul 16 12:59:23 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=30457c62
app-pda/libplist: version bump to 2.2.0
Signed-off-by: Jeffrey Lin <jeffrey <AT> icurse.nl>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>
app-pda/libplist/Manifest | 1 +
app-pda/libplist/libplist-2.2.0.ebuild | 98 ++++++++++++++++++++++++++++++++++
2 files changed, 99 insertions(+)
diff --git a/app-pda/libplist/Manifest b/app-pda/libplist/Manifest
index 9004ee69010..f7eb711f962 100644
--- a/app-pda/libplist/Manifest
+++ b/app-pda/libplist/Manifest
@@ -1 +1,2 @@
DIST libplist-2.1.0.tar.bz2 120602 BLAKE2B
8abfe3c295c4ebd242f2c4d49c80d1f214097df84f1d2fcf2696519bbbca4e8a5ce13c04690ac64fd981f84d585df25fc65c268a4e4f4092319053583e67736c
SHA512
23156e882835bb0b894a05b57018b5e76f9f8f8f4b1d3fdad7b1970d2ef695033c98de74a1fa81bdf0829742a058fd65075cebc1512313d2be42e2f5367274be
+DIST libplist-2.2.0.tar.bz2 126808 BLAKE2B
7c3ec04aaa52eca33ae28851a6524c9ea531df939feef0f10827c8c2de78a6ccd856ea4d8a568b146ccb5de96f70dd5accec34aa2fdd61f9e6eba01256c0b518
SHA512
641bfd3ec0565f104d3a2d1ebdf6137bc9252b67ce90550e24ab0deeee4e820e119ba4f8f1ba04a0358d995d196fa61e35f2f0ee8ba37fc0270752ae842ab1f5
diff --git a/app-pda/libplist/libplist-2.2.0.ebuild
b/app-pda/libplist/libplist-2.2.0.ebuild
new file mode 100644
index 00000000000..7c1f430c30f
--- /dev/null
+++ b/app-pda/libplist/libplist-2.2.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+inherit autotools python-r1 toolchain-funcs
+
+DESCRIPTION="Support library to deal with Apple Property Lists (Binary & XML)"
+HOMEPAGE="https://www.libimobiledevice.org/";
+SRC_URI="https://cgit.libimobiledevice.org/${PN}.git/snapshot/${P}.tar.bz2";
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/3"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="python static-libs"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ virtual/pkgconfig
+ python? ( >=dev-python/cython-0.17[${PYTHON_USEDEP}] )
+"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DOCS=( AUTHORS NEWS README.md )
+
+BUILD_DIR="${S}_build"
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ local ECONF_SOURCE=${S}
+ local myeconfargs=( $(use_enable static-libs static) )
+
+ do_configure() {
+ mkdir -p "${BUILD_DIR}" || die
+ pushd "${BUILD_DIR}" >/dev/null || die
+ econf "${myeconfargs[@]}" "${@}"
+ popd >/dev/null || die
+ }
+
+ do_configure_python() {
+ local -x PYTHON_LDFLAGS="$(python_get_LIBS)"
+ do_configure "$@"
+ }
+
+ # Don't prefer clang.
+ tc-export CC CXX
+
+ do_configure --without-cython
+ use python && python_foreach_impl do_configure_python
+}
+
+src_compile() {
+ python_compile() {
+ emake -C "${BUILD_DIR}"/cython \
+ VPATH="${S}/cython:${native_builddir}/cython" \
+ plist_la_LIBADD="${native_builddir}/src/libplist.la"
+ }
+
+ local native_builddir=${BUILD_DIR}
+ pushd "${BUILD_DIR}" >/dev/null || die
+ emake
+ use python && python_foreach_impl python_compile
+ popd >/dev/null || die
+}
+
+src_test() {
+ emake -C "${BUILD_DIR}" check
+}
+
+src_install() {
+ python_install() {
+ emake -C "${BUILD_DIR}/cython" \
+ VPATH="${S}/cython:${native_builddir}/cython" \
+ DESTDIR="${D}" install
+ }
+
+ local native_builddir=${BUILD_DIR}
+ pushd "${BUILD_DIR}" >/dev/null || die
+ emake DESTDIR="${D}" install
+ use python && python_foreach_impl python_install
+ popd >/dev/null || die
+
+ einstalldocs
+
+ if use python ; then
+ insinto /usr/include/plist/cython
+ doins cython/plist.pxd
+ fi
+
+ find "${D}" -name '*.la' -delete || die
+}
