commit: 356eebba5d87cfaf036e9632c1b014e76d81f61a
Author: Kent Fredric <kentnl <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 2 23:49:14 2020 +0000
Commit: Kent Fredric <kentnl <AT> gentoo <DOT> org>
CommitDate: Thu Jul 2 23:57:39 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=356eebba
dev-perl/Authen-PAM: -r bump for EAPI7 + CFLAGS love
- EAPI7
- Ensure CFLAGS passed to make/compile (existing logic did nothing)
- Simplify + Indent wiki link for readability
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl <AT> gentoo.org>
dev-perl/Authen-PAM/Authen-PAM-0.160.0-r3.ebuild | 51 ++++++++++++++++++++++++
1 file changed, 51 insertions(+)
diff --git a/dev-perl/Authen-PAM/Authen-PAM-0.160.0-r3.ebuild
b/dev-perl/Authen-PAM/Authen-PAM-0.160.0-r3.ebuild
new file mode 100644
index 00000000000..c1487d41ac9
--- /dev/null
+++ b/dev-perl/Authen-PAM/Authen-PAM-0.160.0-r3.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=NIKIP
+DIST_VERSION=0.16
+DIST_EXAMPLES=("test.pl")
+inherit perl-module
+
+DESCRIPTION="Interface to PAM library"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="sys-libs/pam"
+DEPEND="${RDEPEND}"
+BDEPEND="${RDEPEND}"
+
+PATCHES=("${FILESDIR}/no-dot-inc.patch")
+
+src_compile() {
+ mymake=(
+ "OPTIMIZE=${CFLAGS}"
+ )
+ perl-module_src_compile
+}
+
+src_test() {
+ local MODULES=(
+ "Authen::PAM ${DIST_VERSION}"
+ )
+ local failed=()
+ for dep in "${MODULES[@]}"; do
+ ebegin "Compile testing ${dep}"
+ perl -Mblib="${S}" -M"${dep} ()" -e1
+ eend $? || failed+=( "$dep" )
+ done
+ if [[ ${failed[@]} ]]; then
+ echo
+ eerror "One or more modules failed compile:";
+ for dep in "${failed[@]}"; do
+ eerror " ${dep}"
+ done
+ die "Failing due to module compilation errors";
+ fi
+ ewarn "To comprehensively test this module, interactive testing is
necessary"
+ ewarn "For details, see:"
+ ewarn "
https://wiki.gentoo.org/wiki/Project:Perl/maint-notes/${CATEGORY}/${PN}";
+}
