commit: 8c596c03338428080fb50327379d6819cc77fe62
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 29 14:48:25 2020 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Jun 29 14:48:54 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8c596c03
Revert "sys-apps/fwupd: Security cleanup"
This reverts commit 1ce9ba4c9e139be0110a6801d941bd9ea5344ef2
which breaks revdeps on arm
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
sys-apps/fwupd/Manifest | 1 +
sys-apps/fwupd/fwupd-1.2.11.ebuild | 144 +++++++++++++++++++++++++++++++++++++
sys-apps/fwupd/metadata.xml | 1 +
3 files changed, 146 insertions(+)
diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index 109db0674b8..79f3f3a7349 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,3 +1,4 @@
+DIST fwupd-1.2.11.tar.gz 1945646 BLAKE2B
4eb6d5008d0e515880147a94b2632ed70b5f7ab1891775ac121347653c06bf4403ab7f4a1fe160000a6195d360fe06d64c8971dd53c1538aeac40d155f59979a
SHA512
a8d6a76ac59937547c6866d414e95a67779574901b0a15ecfde763f49b434b284be2ade1194179225785006e5f93836667469d08f32d4c87fc85927aa0bfe9de
DIST fwupd-1.3.10.tar.gz 2255394 BLAKE2B
39f517b7648236f39df6f41b5950fcba45a1184f269e533facd752f8e132bb979b32a1420ce4bfcad5bb5d5546ea3f28b357603f7754267550fc02c2125642c5
SHA512
a30ef2933fc01136a9296e99a0b1b9220f952a058aa28339ff944633a8966678b374f479b3a93a1e63bd97491679d3ce304cb621f6e63b86238a8746768daac2
DIST fwupd-1.3.11.tar.gz 2255359 BLAKE2B
0f91c32602459d31e53c63647762307cfe2313c553e16836cc646eb04e3ac54ebd53d2e8615afb7f43b8cd79b7e6315ed688ae04b57de851be62ed6065579ebf
SHA512
e300a84a1c2d7e44e2a1d5d86300487783fc3990b20b540065f9899705569bee8996eae951f32b6fac559e76955ff9b661aa9b181e4dc0211a33a514613ffddd
DIST fwupd-1.4.2.tar.gz 2304086 BLAKE2B
9a725cc49479984c3a98b75e9c52211a26f81d4a7ecec3b261ff4486201a967a6c82df9a1dbd591b91d9cd6eb9d1a8cd8cccfd2c8dd98d5bb3f82cb03bbd0a52
SHA512
b092eedf3e5e84874de1fddb7f14ca87975d5895721ac4f87b6c88ec7c7b2367e573b30906588f9adad4cea52da5ebbaaa4a9c38a2273e8f31d26399e719166e
diff --git a/sys-apps/fwupd/fwupd-1.2.11.ebuild
b/sys-apps/fwupd/fwupd-1.2.11.ebuild
new file mode 100644
index 00000000000..7239b28afea
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.2.11.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit meson python-single-r1 vala xdg-utils
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and
reliable"
+HOMEPAGE="https://fwupd.org";
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="amd64 ~arm x86"
+IUSE="agent colorhug consolekit dell doc elogind +gpg +man nvme pkcs7 redfish
systemd test thunderbolt uefi"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+ ^^ ( consolekit elogind systemd )
+ dell? ( uefi )
+"
+
+RDEPEND="${PYTHON_DEPS}
+ app-arch/gcab
+ app-arch/libarchive:=
+ dev-db/sqlite
+ >=dev-libs/glib-2.45.8:2
+ dev-libs/json-glib
+ dev-libs/libgpg-error
+ dev-libs/libgudev:=
+ >=dev-libs/libgusb-0.2.9[introspection]
+ >=dev-libs/libxmlb-0.1.7
+ $(python_gen_cond_dep '
+ dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+ dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+ dev-python/pygobject:3[cairo,${PYTHON_MULTI_USEDEP}]
+ ')
+ >=net-libs/libsoup-2.51.92:2.4[introspection]
+ >=sys-auth/polkit-0.103
+ virtual/libelf:0=
+ colorhug? ( >=x11-misc/colord-1.2.12:0= )
+ consolekit? ( >=sys-auth/consolekit-1.0.0 )
+ dell? (
+ sys-libs/efivar
+ >=sys-libs/libsmbios-2.4.0
+ )
+ elogind? ( sys-auth/elogind )
+ gpg? (
+ app-crypt/gpgme
+ dev-libs/libgpg-error
+ )
+ nvme? ( sys-libs/efivar )
+ pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
+ redfish? ( sys-libs/efivar )
+ systemd? ( >=sys-apps/systemd-211 )
+ uefi? (
+ media-libs/fontconfig
+ media-libs/freetype
+ sys-boot/gnu-efi
+ >=sys-libs/efivar-33
+ x11-libs/cairo
+ )
+"
+DEPEND="${RDEPEND}
+ $(vala_depend)
+ x11-libs/pango[introspection]
+ nvme? ( >=sys-kernel/linux-headers-4.4 )
+ test? ( net-libs/gnutls[tools] )
+"
+BDEPEND="
+ >=dev-util/meson-0.47.0
+ virtual/pkgconfig
+ doc? ( dev-util/gtk-doc )
+ man? (
+ app-text/docbook-sgml-utils
+ sys-apps/help2man
+ )
+"
+
+# required for fwupd daemon to run.
+# NOT a build time dependency. The build system does not check for dbus.
+PDEPEND="sys-apps/dbus"
+
+src_prepare() {
+ default
+ sed -e "s/'--create'/'--absolute-name', '--create'/" \
+ -i data/tests/builder/meson.build || die
+ sed -e "/'-Werror',/d" \
+ -i plugins/uefi/efi/meson.build || die
+ vala_src_prepare
+}
+
+src_configure() {
+ xdg_environment_reset
+ local emesonargs=(
+ --localstatedir "${EPREFIX}"/var
+ -Dagent="$(usex agent true false)"
+ -Dconsolekit="$(usex consolekit true false)"
+ -Dgtkdoc="$(usex doc true false)"
+ -Delogind="$(usex elogind true false)"
+ -Dgpg="$(usex gpg true false)"
+ -Dman="$(usex man true false)"
+ -Dpkcs7="$(usex pkcs7 true false)"
+ -Dplugin_dell="$(usex dell true false)"
+ # Requires libflashrom which our sys-apps/flashrom
+ # package does not provide
+ -Dplugin_flashrom="false"
+ # Dependencies are not available (yet?)
+ -Dplugin_modem_manager="false"
+ -Dplugin_nvme="$(usex nvme true false)"
+ -Dplugin_redfish="$(usex redfish true false)"
+ -Dplugin_synaptics="$(usex dell true false)"
+ -Dplugin_thunderbolt="$(usex thunderbolt true false)"
+ -Dplugin_uefi="$(usex uefi true false)"
+ -Dsystemd="$(usex systemd true false)"
+ -Dtests="$(usex test true false)"
+ )
+
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+
+ sed "s@%SEAT_MANAGER%@$(usex elogind elogind consolekit)@" \
+ "${FILESDIR}"/${PN}-r1 \
+ > "${T}"/${PN} || die
+ doinitd "${T}"/${PN}
+
+ if ! use systemd ; then
+ # Don't timeout when fwupd is running (#673140)
+ sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+ -i "${ED}"/etc/${PN}/daemon.conf || die
+ fi
+}
+
+pkg_postinst() {
+ elog "In case you are using openrc as init system"
+ elog "and you're upgrading from <fwupd-1.1.0, you"
+ elog "need to start the fwupd daemon via the openrc"
+ elog "init script that comes with this package."
+}
diff --git a/sys-apps/fwupd/metadata.xml b/sys-apps/fwupd/metadata.xml
index 9ff465d6aed..5543dd01883 100644
--- a/sys-apps/fwupd/metadata.xml
+++ b/sys-apps/fwupd/metadata.xml
@@ -8,6 +8,7 @@
<use>
<flag name="agent">Enable update notification agent</flag>
<flag name="amt">Build and install Intel AMT plugin</flag>
+ <flag name="colorhug">Enable ColorHug support
through<pkg>x11-misc/colord</pkg> package</flag>
<flag name="consolekit">Use <pkg>sys-auth/consolekit</pkg> for session
tracking</flag>
<flag name="dell">Enable Dell-specific support.</flag>
<flag name="gpg">Enable GPG support.</flag>
