[gentoo-commits] repo/gentoo:master commit in: dev-perl/Coro/

[Kent Fredric]

commit:     78c238032ec21f94f89ead3a5be214601dba81bc
Author:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 29 11:47:54 2020 +0000
Commit:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
CommitDate: Mon Jun 29 11:48:17 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=78c23803

dev-perl/Coro: -r bump for EAPI7 & CFLAGS love

- EAPI7
- Pass through CFLAGS to make

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl <AT> gentoo.org>

 dev-perl/Coro/Coro-6.514.0-r1.ebuild | 44 ++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

diff --git a/dev-perl/Coro/Coro-6.514.0-r1.ebuild 
b/dev-perl/Coro/Coro-6.514.0-r1.ebuild
new file mode 100644
index 00000000000..beff12e5aaa
--- /dev/null
+++ b/dev-perl/Coro/Coro-6.514.0-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=MLEHMANN
+DIST_VERSION=6.514
+DIST_EXAMPLES=( "eg/*" )
+inherit perl-module
+
+DESCRIPTION="The only real threads in perl"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+ev event"
+
+RDEPEND="
+       >=dev-perl/AnyEvent-5
+       ev? ( >=dev-perl/EV-4.0.0 )
+       event? ( >=dev-perl/Event-0.890.0 )
+       >=dev-perl/Guard-0.500.0
+       virtual/perl-Scalar-List-Utils
+       >=virtual/perl-Storable-2.150.0
+       dev-perl/common-sense
+"
+DEPEND="${RDEPEND}
+       dev-perl/Canary-Stability
+       >=virtual/perl-ExtUtils-MakeMaker-6.520.0
+"
+PATCHES=(
+       "${FILESDIR}/${PV}-ev-config.patch"
+)
+src_configure() {
+       local myopts=()
+       use ev && myopts+=("EV")
+       use event && myopts+=( "Event" )
+       GENTOO_OPTS="${myopts[@]}" perl-module_src_configure
+}
+src_compile() {
+       mymake=(
+               "OPTIMIZE=${CFLAGS}"
+       )
+       perl-module_src_compile
+}