commit: 0ccd0346116f1dd8e2998e6c12c0195339302639
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 21 22:51:39 2020 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu May 28 18:56:12 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0ccd0346
media-sound/audacious: Drop qt5 from 3.10; gtk2-only
Package-Manager: Portage-2.3.94, Repoman-2.3.21
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
media-sound/audacious/audacious-3.10.1-r1.ebuild | 77 ++++++++++++++++++++++++
1 file changed, 77 insertions(+)
diff --git a/media-sound/audacious/audacious-3.10.1-r1.ebuild
b/media-sound/audacious/audacious-3.10.1-r1.ebuild
new file mode 100644
index 00000000000..14d88ac879a
--- /dev/null
+++ b/media-sound/audacious/audacious-3.10.1-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/_/-}"
+
+if [[ ${PV} == *9999 ]]; then
+ inherit autotools git-r3
+ EGIT_REPO_URI="https://github.com/audacious-media-player/audacious.git";
+else
+ SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2";
+ KEYWORDS="amd64 x86"
+fi
+inherit xdg
+
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/";
+SRC_URI+=" mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="nls"
+
+BDEPEND="
+ virtual/pkgconfig
+ nls? ( dev-util/intltool )
+"
+DEPEND="
+ >=dev-libs/dbus-glib-0.60
+ >=dev-libs/glib-2.28
+ >=x11-libs/cairo-1.2.6
+ x11-libs/gtk+:2
+ >=x11-libs/pango-1.8.0
+ virtual/freedesktop-icon-theme
+"
+RDEPEND="${DEPEND}"
+PDEPEND="~media-plugins/audacious-plugins-${PV}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+ default
+ [[ ${PV} == *9999 ]] && git-r3_src_unpack
+}
+
+src_prepare() {
+ default
+ if ! use nls; then
+ sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
+ fi
+ [[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+ # D-Bus is a mandatory dependency, remote control,
+ # session management and some plugins depend on this.
+ # Building without D-Bus is *unsupported* and a USE-flag
+ # will not be added due to the bug reports that will result.
+ # Bugs #197894, #199069, #207330, #208606
+ econf \
+ --disable-valgrind \
+ --enable-dbus \
+ --enable-gtk \
+ --disable-qt \
+ $(use_enable nls)
+}
+
+src_install() {
+ default
+
+ # Gentoo_ice skin installation; bug #109772
+ insinto /usr/share/audacious/Skins/gentoo_ice
+ doins -r "${WORKDIR}"/gentoo_ice/.
+ docinto gentoo_ice
+ dodoc "${WORKDIR}"/README
+}
