commit: 28352d151457a6a27473e2f0e74a211170e83e7a
Author: Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 19 20:25:08 2020 +0000
Commit: Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Apr 19 20:25:33 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=28352d15
net-vpn/networkmanager-wireguard: drop legacy libnm-glib usage
libnm-glib is long gone in NM upstream, so stop providing it as an
option to move forward along with NetworkManager bumps.
Depend on new net-libs/libnma instead of nm-applet, as that's
what's needed and it's split out upstream in newer versions.
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>
...etworkmanager-wireguard-0_pre20191128-r4.ebuild | 61 ++++++++++++++++++++++
1 file changed, 61 insertions(+)
diff --git
a/net-vpn/networkmanager-wireguard/networkmanager-wireguard-0_pre20191128-r4.ebuild
b/net-vpn/networkmanager-wireguard/networkmanager-wireguard-0_pre20191128-r4.ebuild
new file mode 100644
index 00000000000..3a32ea8fbac
--- /dev/null
+++
b/net-vpn/networkmanager-wireguard/networkmanager-wireguard-0_pre20191128-r4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+EGIT_COMMIT="0e1124df9e97129c5e0d9996a2c3876ae18f01c4"
+MY_PN="${PN/network/network-}"
+
+DESCRIPTION="NetworkManager WireGuard plugin"
+HOMEPAGE="https://github.com/max-moser/network-manager-wireguard";
+SRC_URI="https://github.com/max-moser/${MY_PN}/archive/${EGIT_COMMIT}.tar.gz
-> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gtk +nls"
+
+RDEPEND="
+ >=net-misc/networkmanager-1.7.0
+ net-vpn/wireguard-tools[wg-quick]
+ >=dev-libs/glib-2.32:2
+ gtk? (
+ >=x11-libs/gtk+-3.4:3
+ >=net-libs/libnma-1.7.0
+ >=app-crypt/libsecret-0.18
+ )
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+ virtual/pkgconfig
+ nls? (
+ dev-util/intltool
+ sys-devel/gettext
+ )
+"
+
+S="${WORKDIR}/${MY_PN}-${EGIT_COMMIT}"
+
+src_prepare() {
+ default
+
+ eautoreconf
+}
+
+src_configure() {
+ local myeconfargs=(
+ --disable-lto
+ --disable-more-warnings
+ --disable-static
+ $(use_with gtk gnome)
+ --without-libnm-glib
+ $(use_enable nls)
+ --with-dist-version="Gentoo"
+ )
+
+ econf "${myeconfargs[@]}"
+}
