[gentoo-commits] repo/gentoo:master commit in: dev-python/socketpool/

[Michał Górny]

commit:     5639442ef18c497f7d4fe35b1f00af65947a1d8e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 13 07:03:26 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Apr 13 07:07:23 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5639442e

dev-python/socketpool: Add optional dep on eventlet

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/socketpool/metadata.xml               |  4 ++
 dev-python/socketpool/socketpool-0.5.3-r3.ebuild | 62 ++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-python/socketpool/metadata.xml 
b/dev-python/socketpool/metadata.xml
index d9df93424f6..d83b6559d4a 100644
--- a/dev-python/socketpool/metadata.xml
+++ b/dev-python/socketpool/metadata.xml
@@ -10,6 +10,10 @@
     <remote-id type="github">benoitc/socketpool</remote-id>
   </upstream>
   <use>
+    <flag name="eventlet">
+      Install <pkg>dev-python/eventlet</pkg> as needed for the eventlet
+      backend.
+    </flag>
     <flag name="gevent">
       Install <pkg>dev-python/gevent</pkg> as needed for the gevent
       backend.

diff --git a/dev-python/socketpool/socketpool-0.5.3-r3.ebuild 
b/dev-python/socketpool/socketpool-0.5.3-r3.ebuild
new file mode 100644
index 00000000000..144926c2bd4
--- /dev/null
+++ b/dev-python/socketpool/socketpool-0.5.3-r3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A simple Python socket pool"
+HOMEPAGE="https://github.com/benoitc/socketpool/";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="eventlet examples gevent"
+LICENSE="|| ( MIT public-domain )"
+SLOT="0"
+
+RDEPEND="
+       eventlet? (
+               $(python_gen_cond_dep '
+                       dev-python/eventlet[${PYTHON_USEDEP}]
+               ' 'python3*')
+       )
+       gevent? (
+               $(python_gen_cond_dep '
+                       dev-python/gevent[${PYTHON_USEDEP}]
+               ' 'python*')
+       )"
+
+BDEPEND="
+       test? (
+               $(python_gen_cond_dep '
+                       dev-python/eventlet[${PYTHON_USEDEP}]
+               ' 'python3*')
+               !ia64? (
+                       $(python_gen_cond_dep '
+                               dev-python/gevent[${PYTHON_USEDEP}]
+                       ' 'python*')
+               )
+       )"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.5.2-locale.patch )
+
+distutils_enable_tests pytest
+
+python_test() {
+       cp -r examples tests "${BUILD_DIR}" || die
+
+       pushd "${BUILD_DIR}" >/dev/null || die
+       pytest -vv tests || die "Tests fail with ${EPYTHON}"
+       popd >/dev/null || die
+}
+
+python_install_all() {
+       distutils-r1_python_install_all
+
+       use examples && dodoc -r examples
+
+       # package installs unneeded LICENSE files here
+       rm -r "${ED}"/usr/socketpool || die
+}