commit: 7180ba70c31d019e8abe507f7565c0421db8c584
Author: Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 27 23:26:59 2020 +0000
Commit: Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Thu Feb 27 23:26:59 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7180ba70
dev-python/pyftpdlib: bump to 1.5.6, drop Py2
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>
dev-python/pyftpdlib/Manifest | 1 +
dev-python/pyftpdlib/pyftpdlib-1.5.6.ebuild | 86 +++++++++++++++++++++++++++++
2 files changed, 87 insertions(+)
diff --git a/dev-python/pyftpdlib/Manifest b/dev-python/pyftpdlib/Manifest
index 6f3cd9abcf6..6b886a65530 100644
--- a/dev-python/pyftpdlib/Manifest
+++ b/dev-python/pyftpdlib/Manifest
@@ -1 +1,2 @@
DIST pyftpdlib-1.5.5.tar.gz 184314 BLAKE2B
2d02839c6809674c7b7c4dfd610610a9231799802cc53ad0a05bfabc8985e77c64d9b239628f13bdc22942460b3e923067f084c3c5ac2b7be7671279a08e0351
SHA512
27427154f893812f689adf3a9ceb4ec2d8f0ea7a4bf7b08671dc146c95f09ddd596a27c85e009d8d6647277def48c0bf0a8b76fb3fba5818eda3dfdc6c10795e
+DIST pyftpdlib-1.5.6.tar.gz 188099 BLAKE2B
508e94da6b27b4b1f15306df2916c176f07ca31944398e9ac580fca8d2cdc72ca0ee8e7db282de6745e2e401b23b1fa8cb8de400dc2ba998b93ac45772c78157
SHA512
a3c3c1cac221a8a3c090ee208c03134bb1b8de58099a23ca6ee422f06fb97a0ed561c96e62c62b21fa112dd0b3458651b9fc0c55d72dc0bed79d0583b319a50d
diff --git a/dev-python/pyftpdlib/pyftpdlib-1.5.6.ebuild
b/dev-python/pyftpdlib/pyftpdlib-1.5.6.ebuild
new file mode 100644
index 00000000000..a73ad6bcc5e
--- /dev/null
+++ b/dev-python/pyftpdlib/pyftpdlib-1.5.6.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python FTP server library"
+HOMEPAGE="https://github.com/giampaolo/pyftpdlib
https://pypi.org/project/pyftpdlib/";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390
~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos
~sparc-solaris"
+IUSE="examples ssl test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
+ dev-python/pysendfile[${PYTHON_USEDEP}]
+"
+DEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ ${RDEPEND}
+ dev-python/mock[${PYTHON_USEDEP}]
+ dev-python/psutil[${PYTHON_USEDEP}]
+ dev-python/pyopenssl[${PYTHON_USEDEP}]
+ dev-python/pytest[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_sphinx docs dev-python/sphinx_rtd_theme
+
+python_test() {
+ # These tests fail when passing additional options to pytest
+ # so we need to run them separately and not pass any args to pytest
+ pytest ${PN}/test/test_misc.py || die "Tests failed with ${EPYTHON}"
+ # Some of these tests tend to fail
+ local skipped_tests=(
+ # https://github.com/giampaolo/pyftpdlib/issues/470
+ # https://bugs.gentoo.org/659108
+
pyftpdlib/test/test_functional_ssl.py::TestTimeouts::test_idle_data_timeout2
+
pyftpdlib/test/test_functional_ssl.py::TestTimeoutsTLSMixin::test_idle_data_timeout2
+ # https://github.com/giampaolo/pyftpdlib/issues/471
+ # https://bugs.gentoo.org/636410
+
pyftpdlib/test/test_functional.py::TestCallbacks::test_on_incomplete_file_received
+ # https://github.com/giampaolo/pyftpdlib/issues/466
+ # https://bugs.gentoo.org/659786
+
pyftpdlib/test/test_functional_ssl.py::TestFtpListingCmdsTLSMixin::test_nlst
+ # https://github.com/giampaolo/pyftpdlib/issues/512
+ # https://bugs.gentoo.org/701146
+
pyftpdlib/test/test_functional_ssl.py::TestFtpStoreDataTLSMixin::test_rest_on_stor
+
pyftpdlib/test/test_functional_ssl.py::TestFtpStoreDataTLSMixin::test_stor_ascii
+ # https://github.com/giampaolo/pyftpdlib/issues/513
+ # https://bugs.gentoo.org/676232
+
pyftpdlib/test/test_servers.py::TestFtpAuthentication::test_anon_auth
+ # https://github.com/giampaolo/pyftpdlib/issues/513
+ # https://bugs.gentoo.org/702578
+
pyftpdlib/test/test_servers.py::TestFtpAuthentication::test_auth_failed
+ )
+ # Tests fail with TZ=GMT, see https://bugs.gentoo.org/666623
+ TZ=UTC+1 pytest -vv \
+ --ignore ${PN}/test/test_misc.py
${skipped_tests[@]/#/--deselect } \
+ || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+ if use examples; then
+ docinto examples
+ dodoc -r demo/.
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ if [[ -z ${REPLACING_VERSIONS} ]] && \
+ [[ ${PYTHON_TARGETS} == *python2_7* ]] && \
+ ! has_version dev-python/pysendfile ; then
+ elog "dev-python/pysendfile is not installed"
+ elog "It can considerably speed up file transfers for Python 2"
+ fi
+}
