commit: a44751895082bb20bb7d617b3fb814881b4e338e
Author: Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 5 21:56:47 2019 +0000
Commit: Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Thu Sep 5 22:00:03 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a4475189
app-admin/vault: Bump to version 1.2.2
Package-Manager: Portage-2.3.75, Repoman-2.3.17
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>
app-admin/vault/Manifest | 2 +
app-admin/vault/vault-1.2.2.ebuild | 93 ++++++++++++++++++++++++++++++++++++++
2 files changed, 95 insertions(+)
diff --git a/app-admin/vault/Manifest b/app-admin/vault/Manifest
index 1653aa8d29a..902b185fc0f 100644
--- a/app-admin/vault/Manifest
+++ b/app-admin/vault/Manifest
@@ -7,3 +7,5 @@ DIST vault-1.1.2-webui.tar.xz 1281868 BLAKE2B
9c3662dabfd9403fda4a8acd8f9a86ff86
DIST vault-1.1.2.tar.gz 26026601 BLAKE2B
df208b15076007ab87c3c6683698dc4348f56d5a73ff2a52ce17c5a9858acf4d597f7c53f709a1415247cd4cdc65454cc1aa6c18504cbb10368d39df2974175d
SHA512
bc645bc5efeaf5a185479ab2ea78589762d09a40e889845d8cceac94568fcfcfeac94ae602c548648aea800b791121fbb2b75c3af9a9651d08dd9e38c1219826
DIST vault-1.1.3-webui.tar.xz 1284144 BLAKE2B
b84260974ce0827ce8ae834827c331a9bf70f589984975152188615aa480172cf41f4a45abc96fa13bfb7837ae1679bcff519f6aa7ab0678048b2cffbbe11afe
SHA512
36331457c50e2a5d42269a5f91cd3e982c3f7dbfd0a2cfa4f8f435c253af6f075da6401b59a92e1949c683b4c5e899ef2f28bbd8a5cbeabcca8ef30816d75e73
DIST vault-1.1.3.tar.gz 26026249 BLAKE2B
a8fb531caf43f675d604f58126a7e56f7bf86defa2309d5d81d92911457efe5595b5c3244be4d0f73806ca5b746bddc852f871c10841da0e7ec128e53c6c18a4
SHA512
bf757558b984711967fdc623393e71c74d5e73922de3b0574ecb229a5d52320ebc3f848b48eabf0ed7a8d6e9d9f6c12d69fb23309fb8c19492b135344c8c4be2
+DIST vault-1.2.2-webui.tar.xz 1920136 BLAKE2B
81b90a0d796727c7523712ae50f85a24fa98b8b78c304d3ee50654e7f0ea1b3d58005abcbe55a15c3b496f5fce5701306ac57f0c6decc7ab8ae24ab12f5dd81d
SHA512
b454e02e664190903b11bf0e3e465463182f3b7060efeb2c858127306869d731193102ba58398c28441d2be1a3956b88b2591aab1460047647742ba9dab5a00c
+DIST vault-1.2.2.tar.gz 27588019 BLAKE2B
5d989d1750a134f0c68e25ced7406ec8e7ae1d2233a1ece634e1487e4879af2d4a3e938aea1016d6872754f31ef19c85d04cd65e63f6547d7a5cf3cfa93ec208
SHA512
ce9211b3deb1839759646f8488fe2b89fec379bafed472921a62cd507f842ed05647fe4da7cb9482d195b028a29eb576f947da24aecd8b19181c7282fd3a155d
diff --git a/app-admin/vault/vault-1.2.2.ebuild
b/app-admin/vault/vault-1.2.2.ebuild
new file mode 100644
index 00000000000..851d2b1431f
--- /dev/null
+++ b/app-admin/vault/vault-1.2.2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps golang-base golang-vcs-snapshot systemd user
+
+EGO_PN="github.com/hashicorp/${PN}"
+VAULT_WEBUI_ARCHIVE="${P}-webui.tar.xz"
+DESCRIPTION="A tool for managing secrets"
+HOMEPAGE="https://vaultproject.io/";
+SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+ webui? (
+ mirror://gentoo/${VAULT_WEBUI_ARCHIVE}
+ https://dev.gentoo.org/~zmedico/dist/${VAULT_WEBUI_ARCHIVE}
+ )"
+SLOT="0"
+LICENSE="MPL-2.0"
+KEYWORDS="~amd64"
+IUSE="+webui"
+
+RESTRICT="test"
+
+DEPEND=">=dev-lang/go-1.11:=
+ dev-go/gox"
+
+FILECAPS=(
+ -m 755 'cap_ipc_lock=+ep' usr/bin/${PN}
+)
+
+src_unpack() {
+ golang-vcs-snapshot_src_unpack
+ if use webui; then
+ # The webui assets build has numerous nodejs dependencies,
+ # see
https://github.com/hashicorp/vault/blob/master/ui/README.md
+ pushd "${S}/src/${EGO_PN}" >/dev/null || die
+ unpack "${VAULT_WEBUI_ARCHIVE}"
+ popd >/dev/null
+ fi
+}
+
+src_prepare() {
+ default
+ # Avoid the need to have a git checkout
+ sed -e 's:^\(GIT_COMMIT=\).*:\1:' \
+ -e 's:^\(GIT_DIRTY=\).*:\1:' \
+ -e s:\'\${GIT_COMMIT}\${GIT_DIRTY}\':: \
+ -i src/${EGO_PN}/scripts/build.sh || die
+ sed -e "/hooks/d" \
+ -e 's|^\([[:space:]]*\)goimports .*)|\1true|' \
+ -i src/${EGO_PN}/Makefile || die
+
+ # Avoid network-sandbox violations since go-1.13
+ rm src/${EGO_PN}/go.mod || die
+}
+
+pkg_setup() {
+ enewgroup ${PN}
+ enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_compile() {
+ mkdir bin || die
+ export -n GOCACHE XDG_CACHE_HOME #678970
+ export GOBIN=${S}/bin GOPATH=${S}
+ cd src/${EGO_PN} || die
+ # The fmt target may need to be executed if it was previously
+ # executed by an older version of go (bug 665438).
+ emake fmt
+ BUILD_TAGS="$(usex webui ui '')" \
+ XC_ARCH=$(go env GOARCH) \
+ XC_OS=$(go env GOOS) \
+ XC_OSARCH=$(go env GOOS)/$(go env GOARCH) \
+ emake
+}
+
+src_install() {
+ dodoc src/${EGO_PN}/{CHANGELOG.md,CONTRIBUTING.md,README.md}
+ newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+ newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+ insinto /etc/logrotate.d
+ newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+ systemd_dounit "${FILESDIR}/${PN}.service"
+
+ keepdir /etc/${PN}.d
+ insinto /etc/${PN}.d
+ doins "${FILESDIR}/"*.json.example
+
+ keepdir /var/log/${PN}
+ fowners ${PN}:${PN} /var/log/${PN}
+
+ dobin bin/${PN}
+}
