[gentoo-commits] repo/gentoo:master commit in: app-admin/consul-template/

[Zac Medico]

commit:     eceff4849555ae56b144da854755c878c0466f74
Author:     Zac Medico <zachary.medico <AT> sony <DOT> com>
AuthorDate: Fri Jul 26 04:43:50 2019 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Fri Jul 26 04:47:18 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eceff484

app-admin/consul-template: Bump to version 0.20.0

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 app-admin/consul-template/Manifest                 |  1 +
 .../consul-template/consul-template-0.20.0.ebuild  | 66 ++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/app-admin/consul-template/Manifest 
b/app-admin/consul-template/Manifest
index 744e4d45599..681278721ca 100644
--- a/app-admin/consul-template/Manifest
+++ b/app-admin/consul-template/Manifest
@@ -1 +1,2 @@
 DIST consul-template-0.19.5.tar.gz 6054881 BLAKE2B 
48d691f9d09531248310ec50c6c59d3c74db4c8ca5f0236ac8336df92c75da89677e64cb593518032f48f53b9f5aa914a7b6ac0a2dc6bf6d32ae7c1f6d1dc60d
 SHA512 
bdba4e821e353a71f9f6287b8ff352e85a916201314229b998bfbebb066fec17c5d7f12e224bf2920b018a4f5fec9000f122f6c04cb2e455a195b945e35235a5
+DIST consul-template-0.20.0.tar.gz 46430965 BLAKE2B 
025919b928e07cda618e05aab4488214459e6bc443524bbf8fa83331c3ad5708ebbeaf0cf20351ff70a325fb56aed9cede3010b43726fa32b5b1997d6f4f294a
 SHA512 
a09ff31ddd7d11d78e8c2afcc9a63ab4458cc9feacc02fbf95a30c82b9ad58526c6e6575f5b3ddb21d0dd720687b9ee135bacdbe761f1b5f95592a3e3e74c170

diff --git a/app-admin/consul-template/consul-template-0.20.0.ebuild 
b/app-admin/consul-template/consul-template-0.20.0.ebuild
new file mode 100644
index 00000000000..e76748e495c
--- /dev/null
+++ b/app-admin/consul-template/consul-template-0.20.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit golang-vcs-snapshot systemd user
+
+KEYWORDS="~amd64"
+DESCRIPTION="Generic template rendering and notifications with Consul"
+GIT_COMMIT="9a0f301"
+EGO_PN="github.com/hashicorp/${PN}"
+HOMEPAGE="https://github.com/hashicorp/consul-template";
+LICENSE="MPL-2.0"
+SLOT="0"
+# TODO: debug test failures
+RESTRICT="test"
+
+DEPEND="dev-lang/go"
+RDEPEND=""
+
+SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+pkg_setup() {
+       enewgroup ${PN}
+       enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_prepare() {
+       default
+       # Avoid the need to have a git checkout
+       sed -e "s:git rev-parse --short HEAD:echo ${GIT_COMMIT}:" \
+               -e '/-s \\/d' \
+               -i src/${EGO_PN}/Makefile || die
+       # Printf format %q has arg r.config.PidFile of wrong type *string
+       sed -e 's|remove pid at %q: %s|remove pid at %v: %s|' \
+               -i src/${EGO_PN}/manager/runner.go || die
+}
+
+src_compile() {
+       export GOPATH=${S}
+       cd src/${EGO_PN} || die
+       #XC_ARCH=$(go env GOARCH) \
+       #XC_OS=$(go env GOOS) \
+       emake dev
+}
+
+src_test() {
+       cd src/${EGO_PN} || die
+       emake test
+}
+
+src_install() {
+       dobin bin/${PN}
+       dodoc src/${EGO_PN}/{CHANGELOG.md,README.md}
+
+       keepdir /var/log/${PN}
+       fowners ${PN}:${PN} /var/log/${PN}
+
+       newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+       insinto /etc/logrotate.d
+       newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+       newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+       systemd_dounit "${FILESDIR}/${PN}.service"
+
+       keepdir /etc/${PN}.d
+}