commit: 07d47a6c7fef21486a444fd2b308656953a9939e
Author: Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Wed May 8 20:57:01 2019 +0000
Commit: Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Wed May 8 21:10:01 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=07d47a6c
dev-java/openjdk-bin: restrict stipping of binaries
otherwise tools like jmap do not work
Caused by: java.lang.RuntimeException:
unknown CollectedHeap type : class sun.jvm.hotspot.gc_interface.CollectedHeap
Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>
.../openjdk-bin/openjdk-bin-8.212_p03-r1.ebuild | 102 +++++++++++++++++++++
1 file changed, 102 insertions(+)
diff --git a/dev-java/openjdk-bin/openjdk-bin-8.212_p03-r1.ebuild
b/dev-java/openjdk-bin/openjdk-bin-8.212_p03-r1.ebuild
new file mode 100644
index 00000000000..1d7e990563f
--- /dev/null
+++ b/dev-java/openjdk-bin/openjdk-bin-8.212_p03-r1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eapi7-ver java-vm-2
+
+abi_uri() {
+ echo "${2-$1}? (
+
https://github.com/AdoptOpenJDK/openjdk${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jdk_${1}_linux_hotspot_${MY_PV/-/}.tar.gz
+ )"
+}
+
+MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
+SLOT="$(ver_cut 1)"
+
+DESCRIPTION="Prebuilt Java JDK binaries provided by AdoptOpenJDK"
+HOMEPAGE="https://adoptopenjdk.net";
+SRC_URI="
+ $(abi_uri x64 amd64)
+ $(abi_uri ppc64le ppc64)
+"
+
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64 ~ppc64"
+
+IUSE="alsa cups doc examples +gentoo-vm headless-awt nsplugin selinux source
+webstart"
+
+RDEPEND="
+ media-libs/fontconfig:1.0
+ media-libs/freetype:2
+ >=sys-libs/glibc-2.2.5:*
+ sys-libs/zlib
+ alsa? ( media-libs/alsa-lib )
+ cups? ( net-print/cups )
+ doc? ( dev-java/java-sdk-docs:1.${SLOT} )
+ selinux? ( sec-policy/selinux-java )
+ !headless-awt? (
+ x11-libs/libX11
+ x11-libs/libXext
+ x11-libs/libXi
+ x11-libs/libXrender
+ x11-libs/libXtst
+ )"
+
+PDEPEND="webstart? ( >=dev-java/icedtea-web-1.6.1:0 )
+ nsplugin? ( >=dev-java/icedtea-web-1.6.1:0[nsplugin] )"
+
+RESTRICT="preserve-libs strip"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk${MY_PV}"
+
+src_install() {
+ local dest="/opt/${P}"
+ local ddest="${ED}${dest#/}"
+
+ rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
+
+ # this does not exist on arm64 hence -f
+ rm -fv jre/lib/*/libfreetype.so* || die
+
+ if ! use alsa ; then
+ rm -v jre/lib/*/libjsoundalsa.so* || die
+ fi
+
+ if ! use examples ; then
+ rm -vr sample || die
+ fi
+
+ if use headless-awt ; then
+ rm -fvr */jre/lib/*/lib*{[jx]awt,splashscreen}* \
+ {,jre/}bin/policytool bin/appletviewer || die
+ fi
+
+ if ! use source ; then
+ rm -v src.zip || die
+ fi
+
+ dodir "${dest}"
+ cp -pPR * "${ddest}" || die
+
+ use gentoo-vm && java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+ java-vm_set-pax-markings "${ddest}"
+ java-vm_revdep-mask
+ java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+ java-vm-2_pkg_postinst
+
+ if use gentoo-vm ; then
+ ewarn "WARNING! You have enabled the gentoo-vm USE flag, making
this JDK"
+ ewarn "recognised by the system. This will almost certainly
break things."
+ else
+ ewarn "The experimental gentoo-vm USE flag has not been enabled
so this JDK"
+ ewarn "will not be recognised by the system. For example,
simply calling"
+ ewarn "\"java\" will launch a different JVM. This is necessary
until Gentoo"
+ ewarn "fully supports OpenJDK 8. This JDK must therefore be
invoked using its"
+ ewarn "absolute location under ${EPREFIX}/opt/${P}."
+ fi
+}
