commit: 7b778b4efb63f015f53523c4931d2b1ce5bab3ff
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 26 21:21:20 2018 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jun 27 08:44:35 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7b778b4e
dev-util/lldb: Bump to 6.0.1
dev-util/lldb/Manifest | 2 +
dev-util/lldb/lldb-6.0.1.ebuild | 118 ++++++++++++++++++++++++++++++++++++++++
2 files changed, 120 insertions(+)
diff --git a/dev-util/lldb/Manifest b/dev-util/lldb/Manifest
index 8fee9d06831..69fda54a14e 100644
--- a/dev-util/lldb/Manifest
+++ b/dev-util/lldb/Manifest
@@ -1,6 +1,8 @@
DIST lldb-5.0.1.src.tar.xz 19225084 BLAKE2B
82a0f5d40e6278147e4e2d9c7bbf0c19e512ce92c39e4ea0d9a830bf53a343c233aa528ffc3512072017ea2ffc7e6e57d1f13f9bac84a9446e41fb29f35a9da3
SHA512
ebb3c3251098cfce28ccb6a5bbc50491a16b88d1adf3c71fd38efc95482d702e1bd9e7fb11c29597304d97cc0fd88241c70ec11276426aad901e5d23f05ca53a
DIST lldb-5.0.2.src.tar.xz 19220632 BLAKE2B
7ab97a4e96a2faf6593f5584a5455bc793a50a51370bd32d1595958e5fba9d121832675e6f31cb18a3b77b472eefa8040443b77af3e29c5aa455e2a0dcdb7cdc
SHA512
66eaaead60cc908ac061bedb4fac9cb96cecb7f4e5a79a51b6fa080e8f61f718b14e5f3581ead832b495bf10f055d4253d199236a0947dd22395ec80bf2afcf4
DIST lldb-6.0.0.src.tar.xz 19317956 BLAKE2B
e9ebdd61c5116d3e6be3542674b1e3eebba19b4a2107da153565fd95ed24a97248fb80ce5220b4dce2b6e3ac5b61fcdb594e34d6af25e7737575c3f31cd45fbe
SHA512
9679d1dda0c71681b1f8c5a22e775c0262de26dc5b091e1db189968b97ed3aed45991381d529b3fd4b3ab28112453f519045485708f97f765d3e3131b2a918b7
+DIST lldb-6.0.1.src.tar.xz 19292420 BLAKE2B
9ec3304aa370781dcbc7c30e47f7becbd99b50f32d9eea36fefbf0e3608bdfe10796ecc14807ee17795de430409315a5dfad02db0fd3ec1a0ad51e9e240e4b40
SHA512
93ee2efea07276f8838bc2b3ff039cab8c7a1a6965647aaa4dee99f55c6465d5584ed3be87b144e2e32b5acc7db9cec56d89404de764a2f53643ed154d213721
DIST llvm-5.0.1.src.tar.xz 23428720 BLAKE2B
3db4d33df21018d17eef0042c0d8d82a8412bd5daa99cfb5405a6ec83c5774178fa76b220e8731c2a9a64dabf898aa90fe29c685327bd63a4f078e8e94a9a77e
SHA512
bee1d45fca15ce725b1f2b1339b13eb6f750a3a321cfd099075477ec25835a8ca55b5366172c4aad46592dfd8afe372349ecf264f581463d017f9cee2d63c1cb
DIST llvm-5.0.2.src.tar.xz 23451868 BLAKE2B
b7082be2e4ad557b29b9f6869811f262adcf5c73d552faf91b339bede75cf5eab58afefa12fa779a38be71fe2b8f4ea297c3213ee4e8370cc01972c59249d91c
SHA512
3588be5ed969c3f7f6f16f56a12a6af2814d3d3c960d4a36ffebb0446cc75f19220bccee7fc605f9b01f5d5c188a905a046193cc12dec42dd5922048b5c27fe1
DIST llvm-6.0.0.src.tar.xz 25296048 BLAKE2B
7ea90bb63d6f26cfbc1c1ed2f243b0fcd8ad2ceb7963cf768d262cd55e9a0c71a9cfdea0333fb220faacf4540d924d2512532774dcfb52b52490ad74e38c09e0
SHA512
a71fdd5ddc46f01327ad891cfcc198febdbe10769c57f14d8a4fb7d514621ee4080e1a641200d3353c16a16731d390270499ec6cd3dc98fadc570f3eb6b52b8c
+DIST llvm-6.0.1.src.tar.xz 25306628 BLAKE2B
60232d4d22f8096b565cc8d81fea0639f24f14e8fc4f66ade69fa15479181f07f655f26dff3fa24bf105762b495da316c5c9352db234bd0af6b9c3fff6d4d881
SHA512
cbbb00eb99cfeb4aff623ee1a5ba075e7b5a76fc00c5f9f539ff28c108598f5708a0369d5bd92683def5a20c2fe60cab7827b42d628dbfcc79b57e0e91b84dd9
diff --git a/dev-util/lldb/lldb-6.0.1.ebuild b/dev-util/lldb/lldb-6.0.1.ebuild
new file mode 100644
index 00000000000..466d0ecf42e
--- /dev/null
+++ b/dev-util/lldb/lldb-6.0.1.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+# (needed due to CMAKE_BUILD_TYPE != Gentoo)
+CMAKE_MIN_VERSION=3.7.0-r1
+PYTHON_COMPAT=( python2_7 )
+
+inherit cmake-utils llvm multiprocessing python-single-r1 \
+ toolchain-funcs
+
+MY_P=${P/_/}.src
+LLVM_P=llvm-${PV/_/}.src
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="https://llvm.org/";
+SRC_URI="https://releases.llvm.org/${PV/_//}/${MY_P}.tar.xz
+ test? ( https://releases.llvm.org/${PV/_//}/${LLVM_P}.tar.xz )"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="libedit ncurses python test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ libedit? ( dev-libs/libedit:0= )
+ ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+ python? ( dev-python/six[${PYTHON_USEDEP}]
+ ${PYTHON_DEPS} )
+ ~sys-devel/clang-${PV}[xml]
+ ~sys-devel/llvm-${PV}
+ !<sys-devel/llvm-4.0"
+DEPEND="${RDEPEND}
+ python? ( >=dev-lang/swig-3.0.11 )
+ test? ( ~dev-python/lit-${PV}[${PYTHON_USEDEP}] )
+ ${PYTHON_DEPS}"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+S=${WORKDIR}/${MY_P}
+
+# least intrusive of all
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+pkg_setup() {
+ LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
+ python-single-r1_pkg_setup
+}
+
+src_unpack() {
+ einfo "Unpacking ${MY_P}.tar.xz ..."
+ tar -xf "${DISTDIR}/${MY_P}.tar.xz" || die
+
+ if use test; then
+ einfo "Unpacking parts of ${LLVM_P}.tar.xz ..."
+ tar -xf "${DISTDIR}/${LLVM_P}.tar.xz" \
+ "${LLVM_P}"/{lib/Testing/Support,utils/unittest} || die
+ mv "${LLVM_P}" llvm || die
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DLLDB_DISABLE_CURSES=$(usex !ncurses)
+ -DLLDB_DISABLE_LIBEDIT=$(usex !libedit)
+ -DLLDB_DISABLE_PYTHON=$(usex !python)
+ -DLLDB_USE_SYSTEM_SIX=1
+ -DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+ -DLLDB_INCLUDE_TESTS=$(usex test)
+
+ # TODO: fix upstream to detect this properly
+ -DHAVE_LIBDL=ON
+ -DHAVE_LIBPTHREAD=ON
+
+ # normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+ # and TERMINFO_LIBS... so just force FindCurses.cmake to use
+ # ncurses with complete library set (including autodetection
+ # of -ltinfo)
+ -DCURSES_NEED_NCURSES=ON
+ )
+ use test && mycmakeargs+=(
+ -DLLVM_BUILD_TESTS=$(usex test)
+ # compilers for lit tests
+ -DLLDB_TEST_C_COMPILER="$(type -P clang)"
+ -DLLDB_TEST_CXX_COMPILER="$(type -P clang++)"
+
+ -DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+ -DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+ -DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs
"${MAKEOPTS}" "$(get_nproc)")}"
+ )
+
+ cmake-utils_src_configure
+}
+
+src_test() {
+ cmake-utils_src_make check-lldb-lit
+ use python && cmake-utils_src_make check-lldb
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ # oh my...
+ if use python; then
+ # remove custom readline.so for now
+ # TODO: figure out how to deal with it
+ # upstream is basically building a custom readline.so with
-ledit
+ # to avoid symbol collisions between readline and libedit...
+ rm "${D}$(python_get_sitedir)/readline.so" || die
+
+ # byte-compile the modules
+ python_optimize
+ fi
+}
