commit: 394a4d2b906d70a90886917966bb1f702118c5d9
Author: Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 20 18:44:14 2018 +0000
Commit: Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Wed Jun 20 18:46:04 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=394a4d2b
dev-python/flask-wtf: Support Python 3.6, fix dependencies
A lot of the dependencies were missing or not needed. Removing
intersphinx from the doc configuration prevents warning during the doc
build.
Package-Manager: Portage-2.3.40, Repoman-2.3.9
dev-python/flask-wtf/flask-wtf-0.14.2-r1.ebuild | 60 +++++++++++++++++++++++++
1 file changed, 60 insertions(+)
diff --git a/dev-python/flask-wtf/flask-wtf-0.14.2-r1.ebuild
b/dev-python/flask-wtf/flask-wtf-0.14.2-r1.ebuild
new file mode 100644
index 00000000000..785287cca8f
--- /dev/null
+++ b/dev-python/flask-wtf/flask-wtf-0.14.2-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN="Flask-WTF"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Simple integration of Flask and WTForms"
+HOMEPAGE="https://pythonhosted.org/Flask-WTF/
https://pypi.org/project/Flask-WTF/";
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+ dev-python/Babel[${PYTHON_USEDEP}]
+ dev-python/flask[${PYTHON_USEDEP}]
+ dev-python/flask-babel[${PYTHON_USEDEP}]
+ dev-python/itsdangerous[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/werkzeug[${PYTHON_USEDEP}]
+ >=dev-python/wtforms-1.0.5[${PYTHON_USEDEP}]
+"
+DEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ ${RDEPEND}
+ dev-python/nose[${PYTHON_USEDEP}]
+ )
+ doc? (
+ ${RDEPEND}
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+ sed -i "/'sphinx.ext.intersphinx'/d" docs/conf.py || die
+ # tries to access things over the network
+ rm tests/test_recaptcha.py || die
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ sphinx-build docs docs/_build/html || die
+ HTML_DOCS=( docs/_build/html/. )
+ fi
+}
+
+python_test() {
+ nosetests || die "tests failed with ${EPYTHON}"
+}
