[gentoo-commits] repo/gentoo:master commit in: games-arcade/whichwayisup/

[Pacho Ramos]

commit:     79f46506edf99719b830e2d565f82d8d2e36600a
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 24 19:15:43 2018 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Apr 24 19:26:35 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=79f46506

games-arcade/whichwayisup: Stop using games.eclass

Package-Manager: Portage-2.3.31, Repoman-2.3.9

 .../whichwayisup/whichwayisup-0.7.9-r2.ebuild      | 59 ++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/games-arcade/whichwayisup/whichwayisup-0.7.9-r2.ebuild 
b/games-arcade/whichwayisup/whichwayisup-0.7.9-r2.ebuild
new file mode 100644
index 00000000000..84964d15a79
--- /dev/null
+++ b/games-arcade/whichwayisup/whichwayisup-0.7.9-r2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit desktop python-single-r1
+
+MY_PV="${PV//./}"
+MY_P="${PN}_b${MY_PV}"
+
+DESCRIPTION="A traditional and challenging 2D platformer game with a slight 
rotational twist"
+HOMEPAGE="http://hectigo.net/puskutraktori/whichwayisup/";
+SRC_URI="http://hectigo.net/puskutraktori/whichwayisup/${MY_P}.zip";
+
+LICENSE="GPL-2 CC-BY-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+       dev-python/pygame[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+       app-arch/unzip
+"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+       default
+       sed -i \
+               -e "s:libdir\ =\ .*:libdir\ =\ \"/usr/$(get_libdir)/${PN}\":" \
+               run_game.py || die
+       sed -i \
+               -e "s:data_dir\ =\ .*:data_dir\ =\ \"/usr/share/${PN}\":" \
+               lib/data.py || die
+       rm data/pictures/Thumbs.db
+       python_fix_shebang .
+}
+
+src_install() {
+       newbin run_game.py ${PN}
+
+       insinto "/usr/$(get_libdir)/${PN}"
+       doins lib/*.py
+
+       python_optimize "${ED}/usr/$(get_libdir)/${PN}"
+
+       einstalldocs
+
+       insinto "/usr/share/${PN}"
+       doins -r data/*
+
+       newicon "${FILESDIR}"/${PN}-32.xpm ${PN}.xpm
+       make_desktop_entry ${PN} "Which Way Is Up?"
+}