[gentoo-commits] repo/gentoo:master commit in: media-gfx/eog-plugins/

[Pacho Ramos]

commit:     bc9d54fb81cba1597a67b373de977077588ad6bd
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 27 22:01:08 2018 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Feb 27 22:03:33 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bc9d54fb

media-gfx/eog-plugins: Disable support for obsolete postr (#640046)

Package-Manager: Portage-2.3.24, Repoman-2.3.6

 media-gfx/eog-plugins/eog-plugins-3.16.6-r1.ebuild | 63 ++++++++++++++++++++++
 1 file changed, 63 insertions(+)

diff --git a/media-gfx/eog-plugins/eog-plugins-3.16.6-r1.ebuild 
b/media-gfx/eog-plugins/eog-plugins-3.16.6-r1.ebuild
new file mode 100644
index 00000000000..a0b0057c558
--- /dev/null
+++ b/media-gfx/eog-plugins/eog-plugins-3.16.6-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{3_4,3_5,3_6} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Eye of GNOME plugins"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome/Plugins";
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+exif map picasa +python"
+REQUIRED_USE="
+       map? ( exif )
+       python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+RDEPEND="
+       >=dev-libs/glib-2.38:2
+       >=dev-libs/libpeas-0.7.4:=
+       >=media-gfx/eog-3.15.90
+       >=x11-libs/gtk+-3.14:3
+       exif? ( >=media-libs/libexif-0.6.16 )
+       map? (
+               media-libs/libchamplain:0.12[gtk]
+               >=media-libs/clutter-1.9.4:1.0
+               >=media-libs/clutter-gtk-1.1.2:1.0 )
+       picasa? ( >=dev-libs/libgdata-0.9.1:= )
+       python? (
+               ${PYTHON_DEPS}
+               >=dev-libs/glib-2.32:2[dbus]
+               dev-libs/libpeas:=[gtk,python,${PYTHON_USEDEP}]
+               dev-python/pygobject:3[${PYTHON_USEDEP}]
+               gnome-base/gsettings-desktop-schemas
+               media-gfx/eog[introspection]
+               x11-libs/gtk+:3[introspection]
+               x11-libs/pango[introspection] )
+"
+DEPEND="${RDEPEND}
+       >=dev-util/intltool-0.50.1
+       sys-devel/gettext
+       virtual/pkgconfig
+"
+
+pkg_setup() {
+       use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+       local plugins="fit-to-width,send-by-mail,hide-titlebar,light-theme"
+       use exif && plugins="${plugins},exif-display"
+       use map && plugins="${plugins},map"
+       use picasa && plugins="${plugins},postasa"
+       use python && 
plugins="${plugins},slideshowshuffle,pythonconsole,fullscreenbg,export-to-folder,maximize-windows"
+       gnome2_src_configure \
+               $(use_enable python) \
+               --with-plugins=${plugins}
+}