commit: b9d8af593c9c7a0d14f8fa4df134718452dd6814
Author: Sébastien Fabbro <bicatali <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 26 17:21:40 2017 +0000
Commit: Sebastien Fabbro <bicatali <AT> gentoo <DOT> org>
CommitDate: Tue Jun 27 02:48:46 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b9d8af59
dev-python/astroplan: version bump
Package-Manager: Portage-2.3.6, Repoman-2.3.2
dev-python/astroplan/Manifest | 1 +
dev-python/astroplan/astroplan-0.2.1.ebuild | 56 +++++++++++++++++++++++++++++
2 files changed, 57 insertions(+)
diff --git a/dev-python/astroplan/Manifest b/dev-python/astroplan/Manifest
index f1ef68be73b..47546925e30 100644
--- a/dev-python/astroplan/Manifest
+++ b/dev-python/astroplan/Manifest
@@ -1 +1,2 @@
+DIST astroplan-0.2.1.tar.gz 270482 SHA256
eec6c517f46a881e9b24e53afca34b5313e11728739b8f2d32053775bb62befb SHA512
baa585ce2b651753b45c6bda78a93b22340b380197338ce3d27d36509c82c29053da237f1f1daf5c12ba08e0da27f7c3cc98daebedb703c944a3e225444f3aff
WHIRLPOOL
a58611d7b4099b24209dbeea84078794f594a3ee5d088d41ce93ce74c1904c3a4396ea030b0c013973249d53df2d67068f652cf28275d359ba63fb022fbb51e8
DIST astroplan-0.2.tar.gz 264623 SHA256
427d6a890ea7bc4df0b8d0a4b607d060e6e2b230fa1224a648217790d8c1cba7 SHA512
ab98402d2b0daf64aea4a10934c8e33097b92d3b7de9a2346fa3e318e672c85966c050f560bb3fc4c247e2fdd4c94a4b158d6a0dff6af9c83d6411613c663bd9
WHIRLPOOL
6ab4ca9daf2daa8a6a16b06b7287473f149cf3261b2ef35a8f29a24f67e7c0d32edeef59c03fd1fe77f3050670a4c9488b4defe6e417f4925581ca300ca6a8f1
diff --git a/dev-python/astroplan/astroplan-0.2.1.ebuild
b/dev-python/astroplan/astroplan-0.2.1.ebuild
new file mode 100644
index 00000000000..9ed8a4959bf
--- /dev/null
+++ b/dev-python/astroplan/astroplan-0.2.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Observation planning package for astronomers"
+HOMEPAGE="https://astroplan.readthedocs.org/";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+ dev-python/astropy[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+ dev-python/astropy-helpers[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ doc? (
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}] )
+ test? ( dev-python/pytest-mpl[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.2-ephem-import.patch )
+
+python_prepare_all() {
+ # use system astropy-helpers instead of bundled one
+ sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+ xdg_environment_reset
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ if use doc; then
+ python_setup
+ VARTEXFONTS="${T}"/fonts \
+ MPLCONFIGDIR="${BUILD_DIR}" \
+ PYTHONPATH="${BUILD_DIR}"/lib \
+ esetup.py build_sphinx --no-intersphinx
+ fi
+}
+
+python_test() {
+ echo 'backend: Agg' > "${WORKDIR}"/matplotlibrc || die
+ MATPLOTLIBRC="${WORKDIR}" virtx esetup.py test
+}
+
+python_install_all() {
+ use doc && local HTML_DOCS=( docs/_build/html/. )
+ distutils-r1_python_install_all
+}
