commit: cd3cb67c1a414f55c654393a5ae0124eb21001f8
Author: David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 27 18:55:00 2016 +0000
Commit: David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Mar 27 19:04:02 2016 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cd3cb67c
dev-python/pyxattr: Add python3_5 support
Package-Manager: portage-2.2.28
dev-python/pyxattr/pyxattr-0.5.5-r1.ebuild | 56 ++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
diff --git a/dev-python/pyxattr/pyxattr-0.5.5-r1.ebuild
b/dev-python/pyxattr/pyxattr-0.5.5-r1.ebuild
new file mode 100644
index 0000000..06f7f7b
--- /dev/null
+++ b/dev-python/pyxattr/pyxattr-0.5.5-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Python interface to xattr"
+HOMEPAGE="http://pyxattr.k1024.org/";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+ http://pyxattr.k1024.org/downloads/${P}.tar.gz";
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390
~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="sys-apps/attr"
+DEPEND="${RDEPEND}
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ doc? ( >=dev-python/sphinx-1.3.1[${PYTHON_USEDEP}] )
+ test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+ sed -i -e 's:, "-Werror"::' setup.py || die
+ # Bug 548486
+ sed -e "s:html_theme = 'default':html_theme = 'classic':" \
+ -i doc/conf.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ use doc && emake doc
+}
+
+src_test() {
+ # Perform the tests in /var/tmp; that location is more likely
+ # to have xattr support than /tmp which is often tmpfs.
+ export TESTDIR=/var/tmp
+
+ einfo 'Please note that the tests fail if xattrs are not supported'
+ einfo 'by the filesystem used for /var/tmp.'
+ distutils-r1_src_test
+}
+
+python_test() {
+ nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+ use doc && local HTML_DOCS=( doc/html/. )
+ distutils-r1_python_install_all
+}
