commit: da686750672b4adb3312a87a655a89d1129b9cc4
Author: Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Mon Oct 12 13:45:42 2015 +0000
Commit: Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Mon Oct 12 14:30:51 2015 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=da686750
dev-python/pandas: Version Bump
Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org>
dev-python/pandas/Manifest | 1 +
dev-python/pandas/pandas-0.17.0.ebuild | 128 +++++++++++++++++++++++++++++++++
2 files changed, 129 insertions(+)
diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index f1eb82b..e05319e 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -1 +1,2 @@
DIST pandas-0.16.2.tar.gz 4931751 SHA256
e01853dfe111f3aea005315573400b7216ddbabbf1f28d482a71217d67ae4f81 SHA512
44874e12a42a01dd7ed88f3f97e954732a534a5e2dc4815ef6203bdb2d88850a607e6631a35ae8fc79f4621a5dfaa34f39bb1c9a0ecfb17da1cf0c10f35ff27b
WHIRLPOOL
6f2874ac07b49f4b2aaefdb87375b7c5adb31e3ff60c6b808f3e3467ad82999dd894de884ebbfd64fc7235e875d17ce871b516c96ff71a17310b708597168702
+DIST pandas-0.17.0.tar.gz 6508621 SHA256
320d4fdf734b82adebc8fde9d8ca4b05fe155a72b6f7aa95d76242da8748d6a4 SHA512
bae6964e263c7ff6cac722cdfe23081f23c357d9bc39a670b5627bef4630c236a58aa8c0393eae921721bf7049c8e5266b4dea71dd957da5d89dafc14a04797b
WHIRLPOOL
d654eb2f9ffbfedbde60e4a6e6ce6f54650a8a68b4d20035744aa55111525d6bba4dae2ccbfce65acf71bb200e2e6029c7f6c9bcc9d0c582d808444738baedb1
diff --git a/dev-python/pandas/pandas-0.17.0.ebuild
b/dev-python/pandas/pandas-0.17.0.ebuild
new file mode 100644
index 0000000..96b90f0
--- /dev/null
+++ b/dev-python/pandas/pandas-0.17.0.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} )
+
+inherit distutils-r1 eutils flag-o-matic virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="http://pandas.pydata.org/";
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc excel html test R"
+
+EXTRA_DEPEND="
+ >=dev-python/google-api-python-client-1.2.0[$(python_gen_usedep
python2_7 pypy)]
+ dev-python/openpyxl[${PYTHON_USEDEP}]
+ dev-python/pymysql[${PYTHON_USEDEP}]
+ dev-python/python-gflags[$(python_gen_usedep python2_7 pypy)]
+ dev-python/psycopg:2[${PYTHON_USEDEP}]
+ dev-python/statsmodels[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]
+ "
+CDEPEND="
+ >dev-python/numpy-1.7[${PYTHON_USEDEP}]
+ >=dev-python/python-dateutil-2.0[${PYTHON_USEDEP}]
+ !~dev-python/openpyxl-1.9.0[${PYTHON_USEDEP}]"
+DEPEND="${CDEPEND}
+ >=dev-python/cython-0.19.1[${PYTHON_USEDEP}]
+ doc? (
+ dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+ dev-python/ipython[${PYTHON_USEDEP}]
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ >=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+ dev-python/openpyxl[${PYTHON_USEDEP}]
+ >=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ dev-python/rpy[${PYTHON_USEDEP}]
+ sci-libs/scipy[${PYTHON_USEDEP}]
+ >=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
+ dev-python/xlrd[$(python_gen_usedep 'python2_7')]
+ dev-python/xlwt[$(python_gen_usedep 'python2_7')]
+ x11-misc/xclip
+ )
+ test? (
+ ${EXTRA_DEPEND}
+ dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+ dev-python/nose[${PYTHON_USEDEP}]
+ x11-misc/xclip
+ x11-misc/xsel
+ )"
+# dev-python/statsmodels invokes a circular dep
+# hence rm from doc? ( ), again
+RDEPEND="${CDEPEND}
+ >=dev-python/numexpr-2.1[${PYTHON_USEDEP}]
+ dev-python/bottleneck[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ dev-python/pytables[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ sci-libs/scipy[${PYTHON_USEDEP}]
+ excel? (
+ dev-python/xlrd[$(python_gen_usedep 'python2_7')]
+ dev-python/xlwt[$(python_gen_usedep 'python2_7')]
+ || (
+ dev-python/xlsxwriter[${PYTHON_USEDEP}]
+ >=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+ )
+ )
+ html? (
+ dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+ || (
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/html5lib[${PYTHON_USEDEP}] )
+ )
+ R? ( dev-python/rpy[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+ # Prevent un-needed download during build
+ sed -e "/^ 'sphinx.ext.intersphinx',/d" -i
doc/source/conf.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ # To build docs the need be located in $BUILD_DIR,
+ # else PYTHONPATH points to unusable modules.
+ if use doc; then
+ cd "${BUILD_DIR}"/lib || die
+ cp -ar "${S}"/doc . && cd doc || die
+ LANG=C PYTHONPATH=. "${EPYTHON}" make.py html || die
+ fi
+}
+
+python_test() {
+ local test_pandas='not network and not disabled'
+ [[ -n "${FAST_PANDAS}" ]] && test_pandas+=' and not slow'
+ pushd "${BUILD_DIR}"/lib > /dev/null
+ VIRTUALX_COMMAND="nosetests"
+ PYTHONPATH=. MPLCONFIGDIR=. HOME=. \
+ virtualmake --verbosity=3 -A "${test_pandas}" pandas
+ popd > /dev/null
+}
+
+python_install_all() {
+ if use doc; then
+ dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+ einfo "An initial build of docs is absent of references to
statsmodels"
+ einfo "due to circular dependency. To have them included,
emerge"
+ einfo "statsmodels next and re-emerge pandas with USE doc"
+ fi
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ local x
+ elog "Please install"
+ for x in ${EXTRA_DEPEND}; do
+ optfeature "additional functionality" "${x%%[*}"
+ done
+}
